File Coverage

blib/lib/WWW/Compete.pm

Criterion	Covered	Total	%
statement	16	18	88.8
branch			n/a
condition			n/a
subroutine	6	6	100.0
pod			n/a
total	22	24	91.6

package WWW::Compete;

use 5.008008;
use strict;
use warnings;

our $VERSION = '0.03';

use Carp;
use LWP::UserAgent;
use XML::Simple;

use constant COMPETE_VERSION => '3';


# Preloaded methods go here.

sub new {
  my $pkg = shift;

  my $self = {};
  bless $self, $pkg;

  if (! $self->_init(@_)) {
    return undef;
  }

  return $self;
}

sub _init {
  my $self = shift;
  my $args = (ref($_[0]) eq "HASH") ? shift : {@_};

  $self->{'_ver'}        = $args->{'ver'} || COMPETE_VERSION;
  $self->{'_debug'}      = $args->{'debug'};
  $self->{'_key'}        = $args->{'api_key'};
  $self->{'_return_int'} = $args->{'return_int'} || 0;
  $self->{'_ua'}         = LWP::UserAgent->new();

  return 1;
}

sub api_key {
  my $self = shift;
  my $key  = shift;

  if ($key) {
    $self->{'_key'} = $key;
  }

  return $self->{'_key'};
}

sub api_ver {
  my $self = shift;
  my $ver  = shift;

  if ($ver) {
    $self->{'_ver'} = $ver;
  }

  return $self->{'_ver'};
}

sub ua {
  my $self = shift;
  my $ua   = shift;

  if ($ua) {
    $self->{'_ua'}->agent($ua);
  }

  $self->{'_ua'}->agent();
}

sub fetch {
  my $self   = shift;
  my $domain = shift;

  $self->_reset();

  carp("No API key!") && return unless $self->api_key();
  carp("Nothing to fetch!") && return unless $domain;

  $self->{'_current_domain'} = $domain;

  $self->{'_response'} =
    $self->{'_ua'}->get($self->_build_url($domain));

  $self->{'_response_data'} = XMLin($self->{'_response'}->content(),
                                    NormalizeSpace => 2,
                                    SuppressEmpty  => "" );
}

sub get_measurement_yr {
  my $self = shift;

  return $self->{'_response_data'}->{dmn}->{metrics}->{val}->{yr} || "";
}

sub get_measurement_mon {
  my $self = shift;

  return $self->{'_response_data'}->{dmn}->{metrics}->{val}->{mth} || "";
}

sub get_domain {
  my $self = shift;

  return $self->{'_current_domain'} || "";
}

sub get_visitors {
  my $self = shift;

  my $visitors = $self->{'_response_data'}->{dmn}->{metrics}->{val}->{uv}->{count} || "";

  if ($self->{'_return_int'}) {
    $visitors =~ s/[^\d]//g;
    return $visitors;
  } else {
    return $visitors;
  }

}

sub get_rank {
  my $self = shift;

  my $ranking = $self->{'_response_data'}->{dmn}->{metrics}->{val}->{uv}->{ranking} || "";

  if ($self->{'_return_int'}) {
    $ranking =~ s/[^\d]//g;
    return $ranking;
  } else {
    return $ranking;
  }
}

sub get_trust {
  my $self = shift;

  return $self->{'_response_data'}->{dmn}->{trust}->{val} || "";
}

sub get_summary_link {
  my $self = shift;

  $self->{'_response_data'}->{dmn}->{metrics}->{link};
}

sub _build_url {
  my $self   = shift;
  my $domain = shift;

  my $url = 'http://api.compete.com/fast-cgi/MI?d=' . $domain .
            '&ver=' . $self->{'_ver'} .
            '&apikey=' . $self->{'_key'};

  return $url;
}

sub _reset {
  my $self = shift;

  $self->{'_current_domain'} = undef;
  $self->{'_response'}       = undef;
  $self->{'_response_data'}  = undef;
}

1;
__END__