File Coverage

blib/lib/WWW/BackpackTF.pm

Criterion	Covered	Total	%
statement	63	83	75.9
branch	4	8	50.0
condition	1	2	50.0
subroutine	17	21	80.9
pod	6	7	85.7
total	91	121	75.2

package WWW::BackpackTF;

use 5.014000;
use strict;
use warnings;
use parent qw/Exporter/;
our $VERSION = '0.002001';
our @EXPORT_OK = qw/TF2 DOTA2 CSGO/;

use constant +{ ## no critic (Capitalization)
	TF2 => 440,
	DOTA2 => 570,
	CSGO => 730,
	QUALITIES => [qw/Normal Genuine rarity2 Vintage rarity3 Unusual Unique Community Valve Self-Made Customized Strange Completed Haunted Collector's/],
};

BEGIN {
	my @qualities = @{QUALITIES()};
	for (0 .. $#qualities) {
		my $name = uc $qualities[$_];
		$name =~ y/A-Z0-9//cd;
		push @EXPORT_OK, $name;
		constant->import($name, $_)
	}
}

use JSON::MaybeXS qw/decode_json/;
use HTTP::Tiny;
use PerlX::Maybe;
use WWW::BackpackTF::Currency;
use WWW::BackpackTF::Item;
use WWW::BackpackTF::MarketItem;
use WWW::BackpackTF::Listing;
use WWW::BackpackTF::User;

my $ht = HTTP::Tiny->new(agent => "WWW-BackpackTF/$VERSION");

sub request {
	my ($self, $url, %params) = @_;
	$params{key} = $self->{key} if $self->{key};
	$url = $self->{base} . $url;
	$url .= "&$_=$params{$_}" for keys %params;
	my $htr = $ht->get($url);
	die $htr->{reason} unless $htr->{success}; ## no critic (RequireCarping)
	my $response = decode_json($htr->{content})->{response};
	die $response->{message} unless $response->{success}; ## no critic (RequireCarping)
	$response
}

sub new{
	my ($class, %args) = @_;
	$args{base} //= 'http://backpack.tf/api/';
	bless \%args, $class
}

sub get_prices {
	my ($self, $appid, $raw) = @_;
	my $response = $self->request('IGetPrices/v4/?compress=1', maybe appid => $appid, maybe raw => $raw);
	map { WWW::BackpackTF::Item->new($_, $response->{items}{$_}) } keys %{$response->{items}}
}

sub get_users {
	my ($self, @users) = @_;
	my $response = $self->request('IGetUsers/v3/?compress=1', steamids => join ',', @users);
	@users = map { WWW::BackpackTF::User->new($_) } values %{$response->{players}};
	wantarray ? @users : $users[0]
}

sub get_currencies {
	my ($self, $appid) = @_;
	my $response = $self->request('IGetCurrencies/v1/?compress=1', maybe appid => $appid);
	map { WWW::BackpackTF::Currency->new($_, $response->{currencies}{$_}) } keys %{$response->{currencies}};
}

# get_price_history not implemented
# get_special_items not implemented

sub get_market_prices {
	my ($self, $appid) = @_;
	my $response = $self->request('IGetMarketPrices/v1/?compress=1', maybe appid => $appid);
	map { WWW::BackpackTF::MarketItem->new($_, $response->{items}{$_}) } keys %{$response->{items}}
}

sub get_user_listings {
	my ($self, $steamid, $appid) = @_;
	my $response = $self->request('IGetUserListings/v2/?compress=1', steamid => $steamid, maybe appid => $appid);
	map { WWW::BackpackTF::Listing->new($_) } @{$response->{listings}}
}

1;
__END__