File Coverage

blib/lib/Vote/Count/TopCount.pm

Criterion	Covered	Total	%
statement	68	68	100.0
branch	10	10	100.0
condition			n/a
subroutine	12	12	100.0
pod	2	3	66.6
total	92	93	98.9

use strict;
use warnings;
use 5.022;

use feature qw /postderef signatures/;

package Vote::Count::TopCount;
use Moose::Role;

no warnings 'experimental';
use List::Util qw( min max );
use Vote::Count::RankCount;
use TextTableTiny 'generate_markdown_table';
# use boolean;
# use Data::Printer;

our $VERSION='0.007';

=head1 NAME

Vote::Count::TopCount

=head1 VERSION 0.007

=cut

sub TopCount ( $self, $active=undef ) {
  my %ballotset = $self->BallotSet()->%*;
  my %ballots = ( $ballotset{'ballots'}->%* );
  $active = $ballotset{'choices'} unless defined $active ;
  my %topcount = ( map { $_ => 0 } keys( $active->%* ));
TOPCOUNTBALLOTS:
    for my $b ( keys %ballots ) {
      my @votes = $ballots{$b}->{'votes'}->@* ;
      for my $v ( @votes ) {
        if ( defined $topcount{$v} ) {
          $topcount{$v} += $ballots{$b}{'count'};
          next TOPCOUNTBALLOTS;
        }
      }
    }
  return Vote::Count::RankCount->Rank( \%topcount );
}

=head2 TopCountMajority

  $self->TopCountMajority( $round_topcount )
  or
  $self->TopCountMajority( undef, $active_choices )

Will find the majority winner from the results of a topcount, or alternately may be given undef and a hashref of active choices and will topcount the ballotset for just those choices and then find the majority winner.

Returns a hashref of results. It will always include the votes in the round and the thresshold for majority. If there is a winner it will also include the winner and winvotes.

=cut

sub TopCountMajority ( $self, $topcount = undef, $active = undef ) {
  unless ( defined $topcount ) { $topcount = $self->TopCount($active) }
  my $topc = $topcount->RawCount();
  my $numvotes = $topcount->CountVotes();
  my @choices  = keys $topc->%*;
  my $thresshold = 1 + int( $numvotes / 2 );
  for my $t (@choices) {
    if ( $topc->{$t} >= $thresshold ) {
      return (
        {
          votes      => $numvotes,
          thresshold => $thresshold,
          winner     => $t,
          winvotes   => $topc->{$t}
        }
      );
    }
  }
  # No winner
  return (
    {
      votes      => $numvotes,
      thresshold => $thresshold
    }
  );
}

=head2 EvaluateTopCountMajority

This method wraps TopCountMajority adding logging, the logging of which would be a lot of boiler plate in round oriented methods. It takes the same parameters and returns the same hashref.

=cut

sub EvaluateTopCountMajority ( $self, $topcount = undef, $active = undef) {
  my $majority = $self->TopCountMajority( $topcount, $active );
  if ( $majority->{'winner'} ) {
    my $winner = $majority->{'winner'};
    my $rows = [
      [ 'Winner',                    $winner ],
      [ 'Votes in Final Round',      $majority->{'votes'} ],
      [ 'Votes Needed for Majority', $majority->{'thresshold'} ],
      [ 'Winning Votes',             $majority->{'winvotes'} ],
    ];
    $self->logt(
      '---',
      generate_markdown_table(
        rows       => $rows,
        header_row => 0
      )
    );
  }
  return $majority;
}

1;