File Coverage

blib/lib/Versioning/Scheme/Monotonic.pm

Criterion	Covered	Total	%
statement	37	42	88.1
branch	29	36	80.5
condition	14	15	93.3
subroutine	8	9	88.8
pod	5	5	100.0
total	93	107	86.9

package Versioning::Scheme::Monotonic;

our $DATE = '2019-04-14'; # DATE
our $VERSION = '0.010'; # VERSION

use 5.010001;
use strict;
use warnings;

use Role::Tiny::With;
with 'Role::Versioning::Scheme';

our $re = qr/
                \A
                ([1-9][0-9]*)\.                             # 1=compatibility
                ([1-9][0-9]*)                               # 2=release
                (?:\.(0))?                                  # 3=semver_marker
                (?:\+([0-9A-Za-z-]+(?:\.[0-9A-Za-z-]+)*))?  # 4=metadata
                \z
            /x;

sub is_valid_version {
    my ($self, $v) = @_;
    $v =~ $re ? 1:0;
}

sub parse_version {
    my ($self, $v) = @_;
    return undef unless my ($c, $r, $mark, $meta) = $v =~ $re;
    return {
        compatibility => $1,
        release => $2,
        semver_marker => $3,
        metadata => $4,
    };
}

sub normalize_version {
    my ($self, $v, $opts) = @_;
    $opts //= {};

    die "Invalid version '$v'" unless $v =~ $re;

    "$1.$2" . (defined $4 ? ".$4" : "");
}

sub cmp_version {
    my ($self, $v1, $v2) = @_;

    die "Invalid version '$v1'" unless my ($c1, $r1, undef, $m1) = $v1 =~ $re;
    die "Invalid version '$v2'" unless my ($c2, $r2, undef, $m2) = $v2 =~ $re;

    ($c1 <=> $c2) || ($r1 <=> $r2) || (($m1||'') cmp ($m2||''));
}

sub bump_version {
    my ($self, $v, $opts) = @_;
    $opts //= {};
    $opts->{num} //= 1;
    $opts->{part} //= 1;

    die "Invalid version '$v'" unless my ($c, $r, $mark, $meta) = $v =~ $re;
    die "Invalid 'num', must be non-zero" unless $opts->{num} != 0;
    die "Invalid 'part', must be 0|1" unless $opts->{part} =~ /\A(0|1)\z/;

    if ($opts->{part} == 0) {
        if ($c + $opts->{num} < 1) {
            die "Cannot decrease compatibility that would result in zero/negative number";
        }
        if ($r + ($opts->{num} < 0 ? -1 : 1) < 1) {
            die "Cannot decrease compatibility that would result in zero/negative release number";
        }
        $c = $c + $opts->{num};
        $r = $r + ($opts->{num} < 0 ? -1 : 1);
    } else {
        if ($r + $opts->{num} < 1) {
            die "Cannot decrease release that would result in zero/negative number";
        }
        $r = $r + $opts->{num};
    }
    join(
        "",
        $c, ".", $r,
        (defined $mark ? ".$mark" : ""),
        (defined $meta ? ".$meta" : ""),
    );
}

1;
# ABSTRACT: Monotonic versioning

__END__