File Coverage

blib/lib/Version/Next.pm

Criterion	Covered	Total	%
statement	59	59	100.0
branch	29	30	96.6
condition	5	6	83.3
subroutine	7	7	100.0
pod	1	1	100.0
total	101	103	98.0

use strict;
use warnings;

package Version::Next;
# ABSTRACT: increment module version numbers simply and correctly
our $VERSION = '0.004'; # VERSION

# Dependencies
use version 0.81 ();
use Carp ();

# Exporting
use Sub::Exporter 0 ( -setup => { exports => ['next_version'] } );

# lax versions are too lax
sub _cleanup {
    my $version = shift;

    # treat 'undef' as 0
    if ( $version eq 'undef' ) {
        return "0";
    }

    # fix leading dots
    if ( $version =~ /^\./ ) {
        my $num_dots =()= $version =~ /(\.)/g;
        return $num_dots > 1 ? version->parse($version)->normal : "0$version";
    }

    # fix trailing dots
    if ( $version =~ /\.$/ ) {
        # is_lax already prevents dotted-decimal with trailing dot
        return "${version}0";
    }

    # otherwise, it should be fine
    return $version;
}

sub next_version {
    my $version = shift;
    return "0" unless defined $version;

    Carp::croak("Doesn't look like a version number: '$version'")
      unless version::is_lax($version);

    $version = _cleanup($version);

    my $new_ver;
    my $num_dots =()= $version =~ /(\.)/g;
    my $has_v    = $version =~ /^v/;
    my $is_alpha = $version =~ /\A[^_]+_\d+\z/;

    if ( $has_v || $num_dots > 1 ) { # vstring
        $version =~ s{^v}{} if $has_v;
        my @parts = split /\./, $version;
        if ($is_alpha) {             # vstring with alpha
            push @parts, split /_/, pop @parts;
        }
        my @new_ver;
        while (@parts) {
            my $p = pop @parts;
            if ( $p < 999 || !@parts ) {
                unshift @new_ver, $p + 1;
                last;
            }
            else {
                unshift @new_ver, 0;
            }
        }
        $new_ver = $has_v ? 'v' : '';
        $new_ver .= join( ".", map { 0+ $_ } @parts, @new_ver );
        if ($is_alpha) {
            $new_ver =~ s{\A(.*)\.(\d+)}{$1_$2};
        }
    }
    else { # decimal fraction
        my $alpha_neg_offset;
        if ($is_alpha) {
            $alpha_neg_offset = index( $version, "_" ) + 1 - length($version);
            $version =~ s{_}{};
        }
        my ($fraction) = $version =~ m{\.(\d+)$};
        my $n = defined $fraction ? length($fraction) : 0;
        $new_ver = sprintf( "%.${n}f", $version + ( 10**-$n ) );
        if ($is_alpha) {
            substr( $new_ver, $alpha_neg_offset, 0, "_" );
        }
    }
    return $new_ver;

}

1;

__END__