File Coverage

blib/lib/Vector/QRCode/IntoPDF.pm

Criterion	Covered	Total	%
statement	16	18	88.8
branch			n/a
condition			n/a
subroutine	6	6	100.0
pod			n/a
total	22	24	91.6

package Vector::QRCode::IntoPDF;
use 5.008005;
use strict;
use warnings;
use PostScript::Convert;
use PDF::API2;
use Vector::QRCode::EPS;
use File::Temp 'tempdir';
use File::Spec;
use Carp;
use Class::Accessor::Lite (
    new => 0,
    ro => [qw[pdf_file workdir]],
);

our $VERSION = "0.02";

sub new {
    my ($class, %opts) = @_;
    croak 'pdf_file is required' unless $opts{pdf_file};

    $opts{workdir} ||= tempdir(CLEANUP => 1);

    bless {%opts}, $class;
}

sub pdf {
    my $self = shift;
    $self->{__pdf} ||= PDF::API2->open($self->pdf_file) or croak $!;

    $self->{__pdf};
}

sub imprint {
    my ($self, %opts) = @_;

    my %_opts;
    for my $key (qw/x y page/) {
        $_opts{$key} = delete $opts{$key} or croak "$key is required";
    }

    my $qr = $self->_qr_pdf(%opts) or croak "could not create qrcode";
    my $page = $self->pdf->openpage($_opts{page}) or croak "illegal page";
    my $gfx = $page->gfx;

    my $xobj = $self->pdf->importPageIntoForm($qr, 1);
    $gfx->formimage($xobj, $_opts{x}, $_opts{y});
}

sub save {
    my ($self, $path) = @_;
    $path ||= $self->pdf_file;
    $self->pdf->saveas($path);
}

sub _qr_pdf {
    my ($self, %opts) = @_;

    my $qr = Vector::QRCode::EPS->generate(%opts);

    my $qr_data = $qr->get;
    my $qr_pdf = File::Spec->catfile($self->workdir, ($qr+0).'.pdf');

    psconvert(\$qr_data, filename => $qr_pdf, format => 'pdf');

    PDF::API2->open($qr_pdf);
}

1;
__END__