File Coverage

blib/lib/Variable/Lazy.pm

Criterion	Covered	Total	%
statement	59	59	100.0
branch	8	12	66.6
condition	2	6	33.3
subroutine	13	13	100.0
pod			n/a
total	82	90	91.1

package Variable::Lazy;

use strict;
use warnings FATAL => 'all';

our $VERSION = '0.03';
use Variable::Lazy::Guts;

use Devel::Declare;
use B::Hooks::EndOfScope;
use Carp qw/croak/;
use namespace::clean;
our @CARP_NOT = qw/Devel::Declare/;

sub import {
	my $package = caller;

	Devel::Declare->setup_for($package, { lazy => { const => \&_parser } });

	{
		no strict 'refs';
		*{ $package . '::lazy' } = \&Variable::Lazy::Guts::lazy;
	}
	return;
}

sub _parser {
	my ($declarator, $offset) = @_;
	my $linestr = Devel::Declare::get_linestr;
	$offset += Devel::Declare::toke_move_past_token($offset);
	$offset += Devel::Declare::toke_skipspace($offset);

	if (substr($linestr, $offset, 1) eq '{') {
		substr $linestr, $offset, 1, q/(Variable::Lazy::_variable(), \\@_, sub { BEGIN { Variable::Lazy::_inject_scope(')') }; /;
	}
	else {
		if (my $length = Devel::Declare::toke_scan_word($offset, 0)) {
			my $word = substr $linestr, $offset, $length;
			croak "Invalid word '$word' in lazy expression" unless $word eq 'my' or $word eq 'our';
			$offset += $length;
			$offset += Devel::Declare::toke_skipspace($offset);
		}

		croak 'Variable expected' if substr($linestr, $offset, 1) ne '$';
		$offset += Devel::Declare::toke_scan_ident($offset) || croak 'Variable name expected';

		$offset += Devel::Declare::toke_skipspace($offset);

		croak 'Assignment expected' if substr($linestr, $offset, 1) ne '=';
		substr $linestr, $offset++, 1, ',';

		$offset += Devel::Declare::toke_skipspace($offset);

		croak 'Opening bracket expected' if substr($linestr, $offset, 1) ne '{';
		substr $linestr, $offset, 1, q/\\@_, sub { /;
	}
	Devel::Declare::set_linestr($linestr);
	return;
}

sub _variable {
	return my $foo;
}

sub _inject_scope {
	my $terminator = shift;
	on_scope_end {
		my $linestr = Devel::Declare::get_linestr;
		my $offset  = Devel::Declare::get_linestr_offset;
		substr $linestr, $offset, 0, $terminator;
		Devel::Declare::set_linestr($linestr);
	};
	return;
}

1;    # End of Variable::Lazy

__END__