File Coverage

blib/lib/Validator/LIVR/Rules/Filters.pm

Criterion	Covered	Total	%
statement	39	39	100.0
branch	10	10	100.0
condition	20	30	66.6
subroutine	12	12	100.0
pod	0	5	0.0
total	81	96	84.3

package Validator::LIVR::Rules::Filters;

use strict;
use warnings;

our $VERSION = '0.08';

sub trim {
    return sub {
        my ( $value, undef, $output_ref ) = @_;
        return if !defined($value) || ref($value) || $value eq '';

        $$output_ref = $value;
        $$output_ref =~ s/^\s*//;
        $$output_ref =~ s/\s*$//;

        return;
    };
}

sub to_lc {
    return sub {
        my ( $value, undef, $output_ref ) = @_;
        return if !defined($value) || ref($value) || $value eq '';

        $$output_ref = lc($value);
        return;
    };
}

sub to_uc {
    return sub {
        my ( $value, undef, $output_ref ) = @_;
        return if !defined($value) || ref($value) || $value eq '';

        $$output_ref = uc($value);
        return;
    };
}

sub remove {
    my $chars = shift;
    my $re = qr/[\Q$chars\E]/;

    return sub {
        my ( $value, undef, $output_ref ) = @_;
        return if !defined($value) || ref($value) || $value eq '';

        $value =~ s/$re//g;

        $$output_ref = $value;
        return;
    };
}

sub leave_only {
    my $chars = shift;
    my $re = qr/[^\Q$chars\E]/;

    return sub {
        my ( $value, undef, $output_ref ) = @_;
        return if !defined($value) || ref($value) || $value eq '';

        $value =~ s/$re//g;

        $$output_ref = $value;
        return;
    };
}

1;