File Coverage

blib/lib/Validation/Class/Fields.pm

Criterion	Covered	Total	%
statement	43	43	100.0
branch	10	12	83.3
condition	0	2	0.0
subroutine	10	11	90.9
pod	1	1	100.0
total	64	69	92.7

# Container Class for Validation::Class::Field Objects

# Validation::Class::Fields is a container class for L
# objects and is derived from the L class.

package Validation::Class::Fields;

use strict;
use warnings;

use Validation::Class::Util '!has';
use Hash::Flatten ();
use Carp;

our $VERSION = '7.900059'; # VERSION

use base 'Validation::Class::Mapping';

use Validation::Class::Mapping;
use Validation::Class::Field;

sub add {

    my $self = shift;

    my $arguments = $self->build_args(@_);
    my @suspects  = sort keys %{$arguments};

    confess

        "Illegal field names detected, possible attempt to define validation " .
        "rules for a parameter containing an array of nested structures on " .
        "the following fields: " . join ", ", @suspects

        if grep /(:.*:|:\d+.)/, @suspects

    ;

    while (my ($key, $value) = each %{$arguments}) {

        # never overwrite
        unless (defined $self->{$key}) {
            if (isa_hashref($value)) {
                $value->{name} = $key;
            }
            $self->{$key} = $value; # accept an object as a value
            $self->{$key} = Validation::Class::Field->new($value) unless
                "Validation::Class::Field" eq ref $self->{$key}; # unless obj
        }

    }

    return $self;

}

sub AUTOLOAD {

    (my $routine = $Validation::Class::Fields::AUTOLOAD) =~ s/.*:://;

    my ($self) = @_;

    if ($routine) {

        if ($self->has($routine)) {
            return $self->get($routine);
        }

    }

    croak sprintf q(Can't locate object method "%s" via package "%s"),
        $routine, ((ref $_[0] || $_[0]) || 'main')
    ;

}

sub DESTROY {}

1;