File Coverage

blib/lib/Validation/Class/Simple.pm

Criterion	Covered	Total	%
statement	37	42	88.1
branch	0	2	0.0
condition	1	6	16.6
subroutine	12	14	85.7
pod	0	3	0.0
total	50	67	74.6

# ABSTRACT: Simple Ad-Hoc Data Validation

package Validation::Class::Simple;

use 5.10.0;
use strict;
use warnings;

use Validation::Class::Prototype;

use Scalar::Util ('refaddr');
use Validation::Class::Util ('prototype_registry');
use Validation::Class ();

our $VERSION = '7.900058'; # VERSION


sub new {

    my $class = shift;

    $class = ref $class || $class;

    my $self = bless {}, $class;
    my $addr = refaddr $self;

    prototype_registry->add(
        $addr => Validation::Class::Prototype->new(
            package => $class # inside-out prototype
        )
    );

    # let Validation::Class handle arg processing
    $self->Validation::Class::initialize_validator(@_);

    return $self;

}

{

    no strict 'refs';

    # inject prototype class aliases unless exist

    my @aliases = Validation::Class::Prototype->proxy_methods;

    foreach my $alias (@aliases) {

        *{$alias} = sub {

            my ($self, @args) = @_;

            $self->prototype->$alias(@args);

        };

    }

    # inject wrapped prototype class aliases unless exist

    my @wrapped_aliases = Validation::Class::Prototype->proxy_methods_wrapped;

    foreach my $alias (@wrapped_aliases) {

        *{$alias} = sub {

            my ($self, @args) = @_;

            $self->prototype->$alias($self, @args);

        };

    }

}

sub proto { goto &prototype } sub prototype {

    my $self = shift;
    my $addr = refaddr $self;

    return prototype_registry->get($addr);

}

sub DESTROY {

    my $self = shift;
    my $addr = refaddr $self;

    prototype_registry->delete($addr) if $self && prototype_registry;

    return;

}


1;

__END__