File Coverage

blib/lib/VM/HetznerCloud.pm

Criterion	Covered	Total	%
statement	50	50	100.0
branch			n/a
condition			n/a
subroutine	14	14	100.0
pod			n/a
total	64	64	100.0

package VM::HetznerCloud;

use v5.20;

# ABSTRACT: Perl library to work with the API for the Hetzner Cloud

use Moo;
use Mojo::UserAgent;

use Carp;
use Types::Standard qw(Str);
use Types::Mojo qw(:all);

use Mojo::Base -strict, -signatures;
use Mojo::Loader qw(find_modules load_class);
use Mojo::UserAgent;
use Mojo::Util qw(decamelize);

use experimental 'postderef';

our $VERSION = '0.0.3'; # VERSION

has token    => ( is => 'ro', isa => Str, required => 1 );
has host     => ( is => 'ro', isa => MojoURL["https?"], default => sub { 'https://api.hetzner.cloud' }, coerce => 1 );
has base_uri => ( is => 'ro', isa => Str, default => sub { 'v1' } );

has client   => (
    is      => 'ro',
    lazy    => 1,
    isa     => MojoUserAgent,
    default => sub {
        Mojo::UserAgent->new,
    }
);

__PACKAGE__->_load_namespace;

sub _load_namespace ($package) {
    my @modules = find_modules $package . '::API', { recursive => 1 };

    for my $module ( @modules ) {
        load_class( $module );

        my $base = (split /::/, $module)[-1];

        no strict 'refs';  ## no critic
        *{ $package . '::' . decamelize( $base ) } = sub ($api) {
            state $object = $module->new(
                token    => $api->token,
                base_uri => $api->base_uri,
                client   => $api->client,
            );

            return $object;
        };
    }

    return 1;
}

1;

__END__