File Coverage

blib/lib/Unicode/Char.pm

Criterion	Covered	Total	%
statement	54	59	91.5
branch	19	24	79.1
condition			n/a
subroutine	14	17	82.3
pod	4	6	66.6
total	91	106	85.8

package Unicode::Char;
use 5.008001;
use strict;
use warnings;
use Carp;
use charnames ':loose';

our $VERSION = sprintf "%d.%02d", q$Revision: 0.03 $ =~ /(\d+)/g;
our $DEBUG   = 0;

our %Name2Chr;
our %Chr2Name;

sub new {
    my $pkg = shift;
    return bless \eval { my $scalar }, $pkg;
}

sub valid($$) {
    my ( $self, $ord ) = @_;
    return 0 if $ord < 0;
    return 1 if $ord < 0xDC00;       # BMP before surrogates
    return 0 if $ord <= 0xDFFF;      # surrogates
    return 1 if $ord < 0xFFFF;       # BMP after surrogates
    return 0 if $ord == 0xFFFF;      # U+FFFF is invalid
    return 1 if $ord <= 0x10FFFF;    # and to the max;
    return 0;
}

sub names($$) {
    my ( $self, $str ) = @_;
    return map { $self->name($_) } split q() => $str;
}

sub name($$) {
    my ( $self, $char ) = @_;
    return charnames::viacode( ord $char );
}

sub u($$) {
    my ( $self, $hex ) = @_;
    my $ord = hex($hex);
    croak "$ord is invalid" unless $self->valid($ord);
    return chr($ord);
}

sub n($$) {
    my ( $self, $name ) = @_;
    my $char = $Name2Chr{$name};
    return $char
      ? $char
      : $Name2Chr{$name} = eval qq("\\N{$name}");
}

sub DESTROY { }    # so AUTOLOAD will not handle this

sub AUTOLOAD {
    my $method = our $AUTOLOAD;
    $DEBUG and carp $method;
    $method =~ s/.*:://o;
    if ( $method =~ s/^u_?//o ) {
        my $chr = __PACKAGE__->new()->u($method);
        defined $chr or croak "U$method is invalid!";
        no strict 'refs';
        *{$AUTOLOAD} = sub { $chr };
        goto &$AUTOLOAD;
    }
    else {
        my $chr = __PACKAGE__->new()->n($method);
        defined $chr or croak qq(There is no character named "$method");
        no strict 'refs';
        *{$AUTOLOAD} = sub { $chr };
        goto &$AUTOLOAD;
    }
}

1;
__END__