File Coverage

lib/Ubic/AccessGuard.pm

Criterion	Covered	Total	%
statement	36	41	87.8
branch	1	4	25.0
condition			n/a
subroutine	11	12	91.6
pod	1	1	100.0
total	49	58	84.4

package Ubic::AccessGuard;
$Ubic::AccessGuard::VERSION = '1.59';
use strict;
use warnings;

# ABSTRACT: guard for operations with temporarily different effective uid


use Params::Validate;
use Ubic::Result qw(result);
use Ubic::Credentials;
use Carp;
use Scalar::Util qw(weaken);
use Try::Tiny;

# AccessGuard is actually a singleton - there can't be two different guards, since process can't have two euids.
# So we keep weakref to any created AccessGuard.
my $ag_ref;


sub new {
    my $class = shift;
    my ($credentials) = validate_pos(@_, { isa => 'Ubic::Credentials' });

    if ($ag_ref) {
        # oops, another AccessGuard already exists
        my $ag = $$ag_ref;
        if ($ag->{credentials}->eq($credentials)) {
            # new guard is the same as old guard
            return $ag;
        }
        else {
            croak "Can't create AccessGuard for ".$credentials->as_string.", there is already another AccessGuard for ".$ag->{credentials}->as_string;
        }
    }

    my $self = bless {
        credentials => $credentials,
    } => $class;

    try {
        $credentials->set_effective;
    }
    catch {
        die result('unknown', "$_");
    };

    $ag_ref = \$self;
    weaken($ag_ref);

    return $self;
}

sub DESTROY {
    my $self = shift;
    local $@;

    $self->{credentials}->reset_effective;
}


1;

__END__