File Coverage

blib/lib/Types/JsonCoercions.pm

Criterion	Covered	Total	%
statement	19	19	100.0
branch			n/a
condition	2	2	100.0
subroutine	7	7	100.0
pod			n/a
total	28	28	100.0

use 5.008009;
use strict;
use warnings;

package Types::JsonCoercions;

our $AUTHORITY = 'cpan:TOBYINK';
our $VERSION   = '0.001';

use Type::Library 1.004
	-base,
	-declare => qw( ArrayRefJ HashRefJ RefJ StrJ );
use Types::Standard 1.004 qw( Str Ref ArrayRef HashRef );

our $JSON;

sub _code_to_load_package {
	my ( $me, $pkg, $keyword ) = ( shift, @_ );
	$keyword ||= 'do';
	return sprintf(
		'%s { require %s; q[%s] }',
		$keyword,
		$pkg,
		$pkg,
	);
}

sub _code_for_json_encoder {
	my ( $me ) = ( shift );
	return sprintf(
		'$%s::JSON ||= ( %s or %s )->new',
		$me,
		$me->_code_to_load_package( 'JSON::MaybeXS', 'eval' ),
		$me->_code_to_load_package( 'JSON::PP' ),
	);
}

my $meta = __PACKAGE__->meta;

my $ToJson = $meta->add_coercion( {
	name     => 'ToJSON',
	frozen   => 1,
	type_coercion_map => [
		Ref, sprintf( q{ ( %s )->encode( $_ ) }, __PACKAGE__->_code_for_json_encoder ),
	],
} );

my $FromJson = $meta->add_coercion( {
	name     => 'FromJSON',
	frozen   => 1,
	type_coercion_map => [
		Str, sprintf( q{ ( %s )->decode( $_ ) }, __PACKAGE__->_code_for_json_encoder ),
	],
} );

$meta->add_type( {
	name     => StrJ,
	parent   => Str->plus_coercions( $ToJson ),
	coercion => 1,
} );

$meta->add_type( {
	name     => RefJ,
	parent   => Ref->plus_coercions( $FromJson ),
	coercion => 1,
	constraint_generator => sub {
		Ref->of( @_ )->plus_coercions( $FromJson );
	},
} );

$meta->add_type( {
	name     => HashRefJ,
	parent   => HashRef->plus_coercions( $FromJson ),
	coercion => 1,
	constraint_generator => sub {
		HashRef->of( @_ )->plus_coercions( $FromJson );
	},
} );

$meta->add_type( {
	name     => ArrayRefJ,
	parent   => ArrayRef->plus_coercions( $FromJson ),
	coercion => 1,
	constraint_generator => sub {
		ArrayRef->of( @_ )->plus_coercions( $FromJson );
	},
} );

1;

__END__