File Coverage

blib/lib/Types/GitLab.pm

Criterion	Covered	Total	%
statement	21	21	100.0
branch			n/a
condition			n/a
subroutine	7	7	100.0
pod			n/a
total	28	28	100.0

package Types::GitLab;
$Types::GitLab::VERSION = '0.03';
=head1 NAME

Types::GitLab - Type::Tiny types for GitLab stuff.

=head1 SYNOPSIS

  package Foo;

  use Types::GitLab -types;

  use Moo;
  use strictures 1;
  use namespace::clean;

  has token => (
    is  => 'ro',
    isa => GitLabToken,
  );

=head1 DESCRIPTION

L is an open source git server.

This module provides several L types for several of
GitLab's data types.

=cut

use Type::Library -base;
use Type::Utils -all;
use Types::Standard -types;
use Types::Common::Numeric -types;
use URI;

use strictures 1;
use namespace::clean;

=head1 TYPES

=head2 GitLabUsername

Username can contain only letters, digits, '_', '-' and '.'. It must
start with letter, digit or '_', optionally preceeded by '.'. It must
not end in '.git'.

=cut

declare 'GitLabUsername',
  as Str,
  where {
    length($_) > 0 and
    $_ !~ m{[^A-Za-z0-9_.-]} and
    $_ =~ m{^[A-Za-z_]} and
    $_ !~ m{\.git$}
  };

=head2 GitLabToken

The API token for a user.

=cut

declare 'GitLabToken',
  as Str,
  where { length($_) == 20 and $_ !~ m{[^a-zA-Z0-9]} };

=head2 GitLabAPIURI

The value must be an L object.  A coercion is available to
convert a C.

=cut

declare 'GitLabAPIURI',
    as InstanceOf[ 'URI' ];

coerce 'GitLabAPIURI',
    from Str,
    via { URI->new($_) };

=head2 GitLabProjectID

This type requires that the value by a positive integer.

=cut

declare 'GitLabProjectID',
    as PositiveInt;

1;
__END__