File Coverage

blib/lib/Type/Tiny/NumEq.pm

Criterion	Covered	Total	%
statement	41	44	93.1
branch	10	18	55.5
condition	1	3	33.3
subroutine	13	15	86.6
pod	6	6	100.0
total	71	86	82.5

package Type::Tiny::NumEq;
use 5.008001;
use strict;
use warnings;

our $VERSION = "0.02";

use parent qw( Type::Tiny );

sub _croak ($;@) { require Error::TypeTiny; goto \&Error::TypeTiny::croak }

sub new {
    my $class = shift;

    my %opts = ( @_ == 1 ) ? %{ $_[0] } : @_;

    _croak "NumEq type constraints cannot have a parent constraint passed to the constructor"
        if exists $opts{parent};

    _croak "NumEq type constraints cannot have a constraint coderef passed to the constructor"
        if exists $opts{constraint};

    _croak "NumEq type constraints cannot have a inlining coderef passed to the constructor"
        if exists $opts{inlined};

    _croak "Need to supply value" unless exists $opts{value};

    _croak "NumEq value must be defined" unless defined $opts{value};

    {
        use warnings FATAL => 'numeric';
        eval {
            $opts{value} = $opts{value} + 0; # numify
        };
        if ($@) {
            _croak sprintf("`%s` is not number. NumEq value must be number.", $opts{value});
        }
    }

    return $class->SUPER::new( %opts );
}

sub value { $_[0]{value} }

sub _build_display_name {
    my $self = shift;
    sprintf( "NumEq[%s]", $self->value );
}

sub has_parent {
    !!0;
}

sub constraint { $_[0]{constraint} ||= $_[0]->_build_constraint }

sub _build_constraint {
    my $self = shift;
    return sub {
        defined $_ && $_ == $self->value;
    };
}

sub can_be_inlined {
    !!1;
}

sub inline_check {
    my $self = shift;

    my $value = $self->value;
    my $code = "(defined($_[0]) && $_[0] == $value)";

    return "do { $Type::Tiny::SafePackage $code }"
        if $Type::Tiny::AvoidCallbacks; ## no critic (Variables::ProhibitPackageVars)
    return $code;
}

1;
__END__