File Coverage

blib/lib/Type/Coercion/Union.pm

Criterion	Covered	Total	%
statement	40	47	87.2
branch	8	16	50.0
condition			n/a
subroutine	12	13	92.3
pod	3	3	100.0
total	63	79	81.0

package Type::Coercion::Union;

use 5.008001;
use strict;
use warnings;

BEGIN {
	$Type::Coercion::Union::AUTHORITY = 'cpan:TOBYINK';
	$Type::Coercion::Union::VERSION   = '2.002001';
}

$Type::Coercion::Union::VERSION =~ tr/_//d;

use Scalar::Util qw< blessed >;
use Types::TypeTiny ();

sub _croak ($;@) { require Error::TypeTiny; goto \&Error::TypeTiny::croak }

require Type::Coercion;
our @ISA = 'Type::Coercion';

sub _preserve_type_constraint {
	my $self = shift;
	$self->{_union_of} = $self->{type_constraint}->type_constraints
		if $self->{type_constraint};
}

sub _maybe_restore_type_constraint {
	my $self = shift;
	if ( my $union = $self->{_union_of} ) {
		return Type::Tiny::Union->new( type_constraints => $union );
	}
	return;    # uncoverable statement
}

sub type_coercion_map {
	my $self = shift;

	Types::TypeTiny::assert_TypeTiny( my $type = $self->type_constraint );
	$type->isa( 'Type::Tiny::Union' )
		or _croak
		"Type::Coercion::Union must be used in conjunction with Type::Tiny::Union";

	my @c;
	for my $tc ( @$type ) {
		next unless $tc->has_coercion;
		push @c, @{ $tc->coercion->type_coercion_map };
	}
	return \@c;
} #/ sub type_coercion_map

sub add_type_coercions {
	my $self = shift;
	_croak "Adding coercions to Type::Coercion::Union not currently supported"
		if @_;
}

sub _build_moose_coercion {
	my $self = shift;

	my %options = ();
	$options{type_constraint} = $self->type_constraint
		if $self->has_type_constraint;

	require Moose::Meta::TypeCoercion::Union;
	my $r = "Moose::Meta::TypeCoercion::Union"->new( %options );

	return $r;
} #/ sub _build_moose_coercion

sub can_be_inlined {
	my $self = shift;

	Types::TypeTiny::assert_TypeTiny( my $type = $self->type_constraint );

	for my $tc ( @$type ) {
		next       unless $tc->has_coercion;
		return !!0 unless $tc->coercion->can_be_inlined;
	}

	!!1;
} #/ sub can_be_inlined

1;

__END__