File Coverage

lib/Twitter/ID.pm

Criterion	Covered	Total	%
statement	48	48	100.0
branch	28	28	100.0
condition	9	10	90.0
subroutine	9	9	100.0
pod	5	5	100.0
total	99	100	99.0

use v5.26;
use warnings;

package Twitter::ID;
# ABSTRACT: Parse the date from a Twitter Snowflake ID
$Twitter::ID::VERSION = '1.00';

use Carp qw(croak);


my $TW_EPOCH = 1288834974657;
my $WORKER_BITS = 10;
my $SEQUENCE_BITS = 12;

my $TIMESTAMP_SHIFT = $WORKER_BITS + $SEQUENCE_BITS;
my $WORKER_MASK = (-1 ^ (-1 << $WORKER_BITS)) << $SEQUENCE_BITS;
my $SEQUENCE_MASK = -1 ^ (-1 << $SEQUENCE_BITS);
my $MAX_WORKER = 1 << $WORKER_BITS;
my $MAX_SEQUENCE = 1 << $SEQUENCE_BITS;

my $LAST_PRE_SNOWFLAKE_ID = 29700859247;


sub new {
	my ($class, $id) = @_;

	if (ref $id eq 'HASH') {
		my $self = bless \(my $o = 0), $class;
		$self->_set( $id->{timestamp}, $id->{worker}, $id->{sequence} );
		return $self;
	}

	if (! $id) {
		return bless \(my $o = 0), $class;
	}

	bless \$id, $class;
}


sub _set {
	my ($self, $timestamp, $worker, $sequence) = @_;
	$timestamp //= $TW_EPOCH;
	$worker //= 0;
	$sequence //= 0;

	croak "Twitter timestamps before $TW_EPOCH unsupported" if $timestamp < $TW_EPOCH;
	croak "Twitter ID components must be positive" if $worker < 0 || $sequence < 0;
	croak "Worker ID $worker too large (max $MAX_WORKER)" if $worker >= $MAX_WORKER;
	croak "Sequence number $sequence too large (max $MAX_SEQUENCE)" if $sequence >= $MAX_SEQUENCE;

	$$self = ($timestamp - $TW_EPOCH) << $TIMESTAMP_SHIFT
		| $worker << $SEQUENCE_BITS
		| $sequence;
}


sub timestamp {
	my ($self, $timestamp) = @_;

	if (defined $timestamp) {
		$self->_set( $timestamp, $self->worker, $self->sequence );
		return;
	}

	return if $$self <= $LAST_PRE_SNOWFLAKE_ID;

	return ($$self >> $TIMESTAMP_SHIFT) + $TW_EPOCH;
}


sub worker {
	my ($self, $worker) = @_;

	if (defined $worker) {
		$self->_set( $self->timestamp, $worker, $self->sequence );
		return;
	}

	return if $$self <= $LAST_PRE_SNOWFLAKE_ID;

	return ($$self & $WORKER_MASK) >> $SEQUENCE_BITS;
}


sub sequence {
	my ($self, $sequence) = @_;

	if (defined $sequence) {
		$self->_set( $self->timestamp, $self->worker, $sequence );
		return;
	}

	return if $$self <= $LAST_PRE_SNOWFLAKE_ID;

	return $$self & $SEQUENCE_MASK;
}


sub epoch {
	my ($self, $epoch) = @_;

	croak "epoch() is read-only" if defined $epoch;

	my $timestamp = $self->timestamp;
	return unless defined $timestamp;
	return $timestamp / 1000;
}


1;

__END__