File Coverage

blib/lib/Try/Tiny/Warnings.pm

Criterion	Covered	Total	%
statement	31	31	100.0
branch	2	2	100.0
condition			n/a
subroutine	13	13	100.0
pod	0	3	0.0
total	46	49	93.8

package Try::Tiny::Warnings;
our $AUTHORITY = 'cpan:YANICK';
# ABSTRACT: extension to Try::Tiny to also catch warnings
$Try::Tiny::Warnings::VERSION = '0.1.0';

use strict;
use warnings;

use Exporter;
use Try::Tiny;

use parent 'Exporter';

our @EXPORT_OK = qw/ try catch finally /;

our @EXPORT = qw/
    try_warnings
    try_fatal_warnings
    catch_warnings
/;

our %EXPORT_TAGS = (
    'all' => [ @EXPORT, @EXPORT_OK ],
);

sub try_fatal_warnings(&;@) {
    my $sub = shift;

    local $SIG{__WARN__} = sub { die @_ };

    try { $sub->() } @_;
};

sub try_warnings(&;@) {
    my $sub = shift;

    my @warnings;
    local $SIG{__WARN__} = sub { push @warnings, @_ };

    try { $sub->() } map {
        my $x = $_;
        ref $_ eq 'Try::Tiny::Warnings::Catch'
            ? finally { $x->(@warnings) }
            : $_
    } @_;

};

sub catch_warnings(&;@) {
    my $sub = shift;
    return bless( $sub, 'Try::Tiny::Warnings::Catch' ), @_
};

1;

__END__