File Coverage

blib/lib/Try/Chain.pm

Criterion	Covered	Total	%
statement	12	22	54.5
branch	0	4	0.0
condition			n/a
subroutine	4	8	50.0
pod	1	1	100.0
total	17	35	48.5

package Try::Chain; ## no critic (TidyCode)

use strict;
use warnings;
use parent qw(Exporter);
use Try::Tiny qw(try catch finally);

our $VERSION = '0.003';

our @EXPORT_OK = qw( try catch finally try_chain $call_m $fetch_i $fetch_k );

sub try_chain (&;@) { ## no critic (SubroutinePrototypes)
    my ( $chain_code, @more ) = @_;

    my $check_code = sub {
        ## no critic (ComplexRegexes)
        m{
            \A \QCan't call method "\E .*? \Q" on an undefined value\E \b
            | \A \QCan't locate object method "\E .*? \Q" via package\E \b
            | \A \QCan't use an undefined value as a HASH reference\E \b
            | \A \QCan't use an undefined value as an ARRAY reference\E \b
        }xms
            or die $_; ## no critic (RequireCarping)
        ## use critic (ComplexRegexes)

        return ();
    };

    return @more
        ? try {
            try { $chain_code->() } catch { $check_code->() };
        } @more
        : try { $chain_code->() } catch { $check_code->() };
}

our $call_m = sub { ## no critic (PackageVars)
    my ( $self, $method, @more ) = @_;

    return $self ? $self->$method(@more) : ();
};

our $fetch_i = sub { ## no critic (PackageVars)
    my ( $array_ref, $index ) = @_;

    return $array_ref->[$index];
};

our $fetch_k = sub { ## no critic (PackageVars)
    my ( $hash_ref, $key ) = @_;

    return $hash_ref->{$key};
};

# $Id$

1;

__END__