File Coverage

blib/lib/Tropo.pm

Criterion	Covered	Total	%
statement	52	55	94.5
branch	5	8	62.5
condition	4	12	33.3
subroutine	12	12	100.0
pod	0	3	0.0
total	73	90	81.1

package Tropo;

# ABSTRACT: Use the TropoAPI via Perl

use strict;
use warnings;

use Moo;
use Types::Standard qw(ArrayRef);
use Path::Tiny;
use JSON;

use overload '""' => \&json;

our $VERSION = 0.16;

has objects => (
    is      => 'rw',
    isa     => ArrayRef,
    default => sub { [] },
);

for my $subname ( qw(call say ask on wait) ) {
    my $name     = ucfirst $subname;
    my @parts    = qw/Tropo WebAPI/;

    my $filename = path( @parts, $name . '.pm' );
    require $filename;

    my $module = join '::', @parts, $name;

    no strict 'refs';

    *{"Tropo::$subname"} = sub {
        my ($tropo,@params) = @_;

        my $obj = $module->new( @params );
        $tropo->add_object( { $subname => $obj } );

        return $tropo;
    };
}

sub perl {
    my ($self) = @_;

    my @objects;
    my $last_type = '';

    for my $index ( 0 .. $#{ $self->objects } ) {
        my $object      = $self->objects->[$index];
        my $next_object = $self->objects->[$index+1];

        my ($type,$obj) = %{ $object };
        my ($next_type) = %{ $next_object || { '' => ''} };

        if ( $type ne $last_type && $type eq $next_type && $type ne 'on' ) {
            push @objects, { $type => [ $obj->to_hash ] };
        }
        elsif ( $type ne $last_type && $type ne $next_type || $type eq 'on' ) {
            push @objects, { $type => $obj->to_hash };
        }
        else {
            push @{ $objects[-1]->{$type} }, $obj->to_hash;
        }

        $last_type = $type;
    }

    my $data = {
        tropo => \@objects,
    };

    return $data;
}

sub json {
    my ($self) = @_;

    my $data   = $self->perl;
    my $string = JSON->new->encode( $data );

    return $string;
}

sub add_object {
    my ($self, $object) = @_;

    return if !$object;

    push @{ $self->{objects} }, $object;
}

1;

__END__