File Coverage

blib/lib/Tree/Simple/Visitor/PostOrderTraversal.pm

Criterion	Covered	Total	%
statement	30	30	100.0
branch	6	6	100.0
condition	7	9	77.7
subroutine	7	7	100.0
pod	2	2	100.0
total	52	54	96.3

package Tree::Simple::Visitor::PostOrderTraversal;

use strict;
use warnings;

our $VERSION = '0.14';

use Scalar::Util qw(blessed);

use base qw(Tree::Simple::Visitor);

sub new {
    my ($_class) = @_;
    my $class = ref($_class) || $_class;
    my $visitor = {};
    bless($visitor, $class);
    $visitor->_init();
    return $visitor;
}

sub visit {
	my ($self, $tree) = @_;
	(blessed($tree) && $tree->isa("Tree::Simple"))
		|| die "Insufficient Arguments : You must supply a valid Tree::Simple object";
    # get our filter function
    my $filter_function = $self->getNodeFilter();
    # use an inner subroutine to accomplish
    # this traversal using recursion
    my $_postOrderTraversal = sub {
        my ($current_tree, $traversal_function) = @_;
        # get a temporary results container
        my @results;
        # process each child
        foreach my $child ($current_tree->getAllChildren()) {
            # recurse our inner subroutine by passing itself
            # to itself, and then collect the results of this
            # recursion
            push @results => $traversal_function->($child, $traversal_function);
        }
        # if we are root and we are not including the trunk then
        # we can return our results now
        return @results if $current_tree->isRoot() && !$self->includeTrunk();
        # however, if we don't meet those conditions, then we
        # need to process the current tree and add it to our
        # results
        push @results => (($filter_function) ?
                                $filter_function->($current_tree)
                                :
                                $current_tree->getNodeValue());
        # and then return the results
        return @results;
    };
    # now store the results in our object
    $self->setResults($_postOrderTraversal->($tree, $_postOrderTraversal));
}

1;

__END__