File Coverage

blib/lib/Time/TimeTick.pm

Criterion	Covered	Total	%
statement	46	46	100.0
branch	11	14	78.5
condition	4	6	66.6
subroutine	15	15	100.0
pod	3	3	100.0
total	79	84	94.0

package Time::TimeTick;

use 5.006;
use strict;
use warnings;
use Exporter;
use File::Basename;

our @ISA     = qw(Exporter);
our @EXPORT  = qw(timetick);   # Although we override Exporter's import()
our $VERSION = '0.06';

my @Tix;           # Where we keep the time ticks
our %Opt;          # Global option setting interface
my $Epoch = $^T;   # Point from which times are measured

sub import
{
  my $class = shift;
  %Opt = @_;

  eval { require Time::HiRes };
  $Epoch = _current_time() if $Opt{reset_start};

  unless ($Opt{suppress_initial})
  {
    my $prog = basename($0);
    timetick($Opt{initial_tag} || "Timeticker for $prog starting");
  }

  $class->export_to_level(1, @EXPORT);
}


sub unimport
{
  my $class = shift;
  %Opt = @_;
  no warnings 'redefine';
  *timetick = sub { };
  $class->export_to_level(1, @EXPORT);
}


sub timetick
{
  my $tag = pop;
  $Opt{format_tick_tag} and $tag = $Opt{format_tick_tag}->($tag);
  push @Tix, [ _current_time() - $Epoch, $tag ];
}


sub _current_time
{
  exists &Time::HiRes::time ? Time::HiRes::time() : time;
}


sub report
{
  unless ($Opt{suppress_report})
  {
    &{ $Opt{format_report} || \&_format_report }(@Tix);
  }

  @Tix = ();
}


sub _format_report
{
  printf("%7.4f %s\n", @$_) for @_;
}


sub end
{
  unless ($Opt{suppress_final})
  {
    my $prog = basename($0);
    timetick($Opt{final_tag} || "Timeticker for $prog finishing");
  }

  report();
}


END { end() }

1;

__END__