File Coverage

blib/lib/Time/Spent.pm

Criterion	Covered	Total	%
statement	52	52	100.0
branch	14	16	87.5
condition	5	6	83.3
subroutine	12	12	100.0
pod	5	6	83.3
total	88	92	95.6

package Time::Spent;
# ABSTRACT: Track events and calculate a rolling average of time, er, spent
$Time::Spent::VERSION = '0.02';
use strict;
use warnings;
use Carp;
use Time::HiRes qw( );
use List::Util  qw( );

sub ts { Time::HiRes::time }

sub param (\%$;$) {
  my ( $param, $name, $default ) = @_;

  croak "expected parameter '$name'"
      if !exists $param->{ $name }
      && !defined $default;

  return $default unless exists $param->{ $name };
  return $param->{ $name };
}


sub new {
  my ( $class, %param ) = @_;
  my $length = param %param, 'length', undef;

  croak "parameter 'length' expected a positive integer"
    unless $length =~ /^\d*$/
        && $length > 0;

  my $self = {
    length  => $length,
    count   => 0,
    tracked => { },
    history => [ ],
    average => undef,
  };

  return bless $self, $class;
}


sub start {
  my $self = shift;

  croak 'expected one or more identifiers'
    unless @_;

  foreach ( @_ ) {
    croak "already tracking $_"
      if $self->is_tracking( $_ )
  }

  my $ts = ts;
  $self->{ tracked }{ $_ } = $ts foreach @_;

  return @_;
}


sub stop {
  my $self = shift;

  croak 'expected one or more identifiers'
    unless @_;

  foreach ( @_ ) {
    croak "not tracking $_"
      unless $self->is_tracking( $_ )
  }

  my $ts = ts;

  foreach ( @_ ) {
    my $spent = $ts - $self->{ tracked }{ $_ };
    delete $self->{ tracked }{ $_ };

    push @{ $self->{ history } }, $spent;
    ++$self->{ count };
  }

  while ( $self->{ count } > $self->{ length } ) {
    shift @{ $self->{ history } };
    --$self->{ count };
  }

  $self->{ average } = List::Util::sum0( @{ $self->{ history } } ) / $self->{ count };

  return @_;
}


sub avg { $_[ 0 ]->{ average } }


sub is_tracking { exists $_[ 0 ]->{ tracked }{ $_[ 1 ] } ? 1 : 0 }

1;

__END__