File Coverage

blib/lib/Time/Consts.pm

Criterion	Covered	Total	%
statement	28	29	96.5
branch	8	8	100.0
condition	3	3	100.0
subroutine	4	5	80.0
pod			n/a
total	43	45	95.5

package Time::Consts;

$VERSION = 0.03;

use strict;
use Carp;

my %ok = map { $_ => 1 } qw/
    MSEC
    SEC
    MIN
    HOUR
    DAY
    WEEK
/;

my %secs = (
    MSEC => 1,
    SEC  => 1000 * 1,
    MIN  => 1000 * 60,
    HOUR => 1000 * 60 * 60,
    DAY  => 1000 * 60 * 60 * 24,
    WEEK => 1000 * 60 * 60 * 24 * 7,
);

sub import {
    shift;

    return unless @_;

    my @args = @_;

    if (my (@bad) = grep !$ok{+uc} && $_ ne ':ALL' => @args) {
        croak('Bad argument(s): ' . join ', ' => @bad);
    }

    my @unit = grep $_ eq lc, @args;
    croak("Too many units: @unit") if @unit > 1;
    push @unit => 'sec';
    my $unit = $secs{uc $unit[0]};

    my @consts = keys %{{
        map { $_ => 1 }
        map { $_ eq ':ALL' ? keys %ok : $_ }
        grep { $_ eq uc }
        @args
    }};

    my $pkg = caller;

    for (@consts) {
        my $t = $secs{$_} / $unit;

        no strict 'refs';
        *{"$pkg\::$_"} = sub () { $t };
    }
}

__PACKAGE__;

__END__