File Coverage

blib/lib/Time/C.pm

Criterion	Covered	Total	%
statement	91	98	92.8
branch	2	4	50.0
condition	6	15	40.0
subroutine	29	32	90.6
pod	5	5	100.0
total	133	154	86.3

use strict;
use warnings;
package Time::C;
$Time::C::VERSION = '0.001';
# ABSTRACT: Convenient time manipulation.

use Carp qw/ croak /;
use overload (
    '""' => sub { shift->string },
    fallback => 1,
);
use Time::Moment;
use Sentinel;

use Time::C::Val;

sub _build {
    my $meth = shift;
    my $class = shift;
    my $tm = Time::Moment->$meth(@_);

    bless { tm => $tm }, $class;
}

my @accessors = (qw/
  year month week hour minute second millisecond microsecond nanosecond /);
my @new_accs = (qw/ epoch jd mjd rd /);
my @day_accs = (qw/ day_of_month day_of_week day_of_year day_of_quarter /);

sub _acc :lvalue {
    my $val = shift;
    my $self = shift;
    $self->_apply();

    $self->{$val} //= Time::C::Val->new(
      val => $self->{tm}->$val(), self => $self, acc => $val);
    sentinel value => $self->{$val}, set =>
      sub { $self->{$val} = $_[0]; $self->_apply() };
}

sub _new_acc :lvalue {
    my $val = shift;
    my $self = shift;
    $self->_apply();

    $self->{$val} = $self->{tm}->$val();
    sentinel value => $self->{$val}, set =>
      sub { $self->{$val} = $_[0]; $self->_apply() };
}

sub _day_acc :lvalue {
    my $val = shift;
    my $self = shift;
    $self->_apply();

    $self->{$val} //= Time::C::Val->new(
      val => $self->{tm}->$val(), self => $self, acc => $val, meth => 'day');
    sentinel value => $self->{$val}, set =>
      sub { $self->{$val} = $_[0]; $self->_apply() };
}

sub _apply {
    my $self = shift;
    foreach my $acc (grep { exists $self->{$_} }
      @accessors, @day_accs, 'offset', 'quarter') {
        my $meth = "with_$acc";
        eval {
            $self->{tm} = $self->{tm}->$meth(delete $self->{$acc});
            1;
        } or croak "$@";
    }
    foreach my $acc (grep { exists $self->{$_} } @new_accs, 'string') {
        my $meth = "from_$acc";
        eval {
            $self->{tm} = Time::Moment->$meth(delete $self->{$acc});
            1;
        } or croak "$@";
    }
}

# constructors

for my $const (qw/ new now now_utc from_epoch from_object from_string from_rd
  from_jd from_mjd /) {
    no strict 'refs';
    *$const = sub { _build($const, @_); };
}

# accessors

for my $acc (@accessors) {
    no strict 'refs';
    *$acc = sub :lvalue { _acc($acc, @_); };
}

for my $acc (@new_accs) {
    no strict 'refs';
    *$acc = sub :lvalue { _new_acc($acc, @_); };
}

for my $acc (@day_accs) {
    no strict 'refs';
    *$acc = sub :lvalue { _day_acc($acc, @_); };
}

sub string :lvalue {
    my $self = shift;
    $self->_apply();

    $self->{string} //= "$self->{tm}";
    sentinel value => $self->{string}, set =>
      sub { $self->{string} = $_[0]; $self->_apply() };
}

sub tm :lvalue {
    my $self = shift;
    $self->_apply();

    $self->{tm};
}

sub day :lvalue {
    shift->day_of_month();
}

sub offset :lvalue {
    my $self = shift;
    $self->_apply();

    $self->{offset} //= $self->{tm}->offset();
    sentinel value => $self->{offset}, set =>
      sub { $self->{offset} = $_[0]; $self->_apply() };
}

sub quarter :lvalue {
    my $self = shift;
    $self->_apply();

    $self->{quarter} //= $self->{tm}->quarter();
    sentinel value => $self->{quarter}, set =>
      sub { $self->{quarter} = $_[0]; $self->_apply() };
}

1;

__END__