File Coverage

blib/lib/Tie/Sub.pm

Criterion	Covered	Total	%
statement	31	31	100.0
branch	8	8	100.0
condition			n/a
subroutine	7	7	100.0
pod	1	1	100.0
total	47	47	100.0

package Tie::Sub; ## no critic (TidyCode)

use strict;
use warnings;

our $VERSION = '1.001';

use Carp qw(confess);
use Params::Validate qw(:all);

## no critic (ArgUnpacking)

sub TIEHASH {
    my ($class, $code_ref) = validate_pos(
        @_,
        {type => SCALAR},
        {type => CODEREF, optional => 1},
    );

    my $scalar;
    my $self = bless \$scalar, $class;
    if ($code_ref) {
        $self->config($code_ref);
    }

    return $self;
}

# configure
sub config {
    # object, parameter
    my ($self, $code_ref) = validate_pos(
        @_,
        {isa  => __PACKAGE__},
        {type => CODEREF, optional => 1},
    );

    my $previous_code_ref = ${$self};
    if ($code_ref) {
        ${$self} = $code_ref;
    }

    return $previous_code_ref;
}

# execute the code reference
sub FETCH {
    # object, key
    my ($self, $key) = validate_pos(
        @_,
        {isa  => __PACKAGE__},
        {type => SCALAR | ARRAYREF},
    );

    ${$self} or confess 'Call of method "config" is necessary';

    # Several parameters to the subroutine will submit as reference on an array.
    return ${$self}->(
        ref $key eq 'ARRAY'
        ? @{$key}
        : $key
    );
}

# $Id$

1;

__END__