File Coverage

blib/lib/Text/Xslate/Bridge/Star.pm

Criterion	Covered	Total	%
statement	43	46	93.4
branch	29	36	80.5
condition	0	3	0.0
subroutine	13	13	100.0
pod	8	8	100.0
total	93	106	87.7

package Text::Xslate::Bridge::Star;
use strict;
use warnings;
use parent qw(Text::Xslate::Bridge);

BEGIN {
    if(my $code = re->can('is_regexp')) {
        *_is_rx = $code;
    }
    else {
        require Scalar::Util;
        *_is_rx = sub {
            return Scalar::Util::blessed($_[0])
                && $_[0]->isa('Regexp');
        };
    }
}

sub lc {
    return defined($_[0]) ? CORE::lc($_[0]) : undef;
}

sub uc {
    return defined($_[0]) ? CORE::uc($_[0]) : undef;
}

sub substr {
    my($str, $offset, $length) = @_;
    return undef unless defined $str;
    $offset = 0 unless defined $offset;
    $length = length($str) unless defined $length;
    return CORE::substr($str, $offset, $length);
}


sub sprintf {
    my $fmt = shift;
    return undef unless defined $fmt;
    if(@_) { # sprintf($fmt, ...)
        return sprintf $fmt, @_;
    }
    else { # $x | sprintf('%.02f')
        return sub {
            sprintf $fmt, @_;
        };
    }
}

sub rx {
    return defined($_[0]) ? qr/$_[0]/ : undef;
}

sub match {
    my($str, $pattern) = @_;
    return undef unless defined $str;
    return undef unless defined $pattern;

    $pattern = quotemeta($pattern) unless _is_rx($pattern);
    return scalar($str =~ m/$pattern/);
}

sub replace {
    my($str, $pattern, $replacement) = @_;
    return undef unless defined $str;
    return undef unless defined $pattern;

    $pattern = quotemeta($pattern) unless _is_rx($pattern);
    $str =~ s/$pattern/$replacement/g;
    return $str;
}

sub split {
    my($str,$pattern,$limit) = @_;
    if (!defined $pattern) {
        $pattern = ' ';
    }
    $pattern = quotemeta($pattern) unless _is_rx($pattern);
    if (defined $limit) {
        return [CORE::split($pattern, $str, $limit)];
    } else {
        return [CORE::split($pattern, $str)];
    }
}

my %scalar_methods = (
    lc      => \&lc,
    uc      => \&uc,
    substr  => \&substr,
    sprintf => \&sprintf,
    rx      => \&rx,
    match   => \&match,
    replace => \&replace,
    split   => \&split,
);

__PACKAGE__->bridge(
#    nil    => \%nil_methods,
    scalar => \%scalar_methods,
#    array  => \%array_methods,
#    hash   => \%hash_methods,

    function => \%scalar_methods,
);

1;
__END__