File Coverage

blib/lib/Text/Tweet.pm

Criterion	Covered	Total	%
statement	62	66	93.9
branch	25	28	89.2
condition	5	6	83.3
subroutine	8	10	80.0
pod	0	4	0.0
total	100	114	87.7

package Text::Tweet;
BEGIN {
  $Text::Tweet::AUTHORITY = 'cpan:GETTY';
}
BEGIN {
  $Text::Tweet::VERSION = '0.004';
}
# ABSTRACT: Optimize a tweet based on given keywords

use Moo;
use Text::Trim;


has maxlen => (
	is => 'ro',
	default => sub { 140 },
);

has marker => (
	is => 'ro',
	default => sub { '#' },
);

# TODO
has marker_re => (
	is => 'ro',
	default => sub { '\#' },
);

has hashtags_at_end => (
	is => 'ro',
	default => sub { 0 },
);

has keywords => (
	is => 'ro',
	default => sub {[]},
);

# TODO - mappings
has mappings => (
	is => 'ro',
	default => sub {{}},
);

sub make_tweet {
	my ( $self, $text, $url, $keywords ) = @_;
	warn '['.__PACKAGE__.'] This function is DEPRECATED, use ->make($text,\$url,\@keywords)'."\n";
	return $self->make($text,\$url,$keywords);
}

sub make {
	my $self = shift;
	return $self->_generate_tweet( $self->keywords, @_ );
}

sub make_without_keywords { shift->_generate_tweet(@_) }

sub parts_length {
	my @parts;
	for (@_) {
		if (ref $_ eq 'SCALAR') {
			push @parts, ${$_};
		} else {
			push @parts, $_;
		}
	}
	length(join(' ',@parts));
}

sub _generate_tweet {
	my $self = shift;

	my @keywords;
	my @parts;

	for my $part (@_) {
		my $newpart;
		if (ref $part eq 'ARRAY') {
			push @keywords, @{$part};
		} elsif (ref $part eq 'HASH') {
			# TODO - mappings
		} elsif (ref $part eq 'SCALAR') {
			my $scalar_newpart = \trim(join(' ',split(/[\n\r\t ]+/,${$part})));
			$newpart = $scalar_newpart if ${$scalar_newpart};
		} else {
			$newpart = trim(join(' ',split(/[\n\r\t ]+/,scalar $part)));
		}
		push @parts, $newpart if $newpart;
	}

	my @newparts;
	my @used_keywords;
	my $marker = $self->marker;
	my $marker_re = $self->marker_re;
	for my $keyword (@keywords) {

		if (!grep { lc($_) eq lc($keyword) } @used_keywords) {
			push @used_keywords, $keyword;

			my $count = parts_length(@parts,@newparts);
			last if $count + 1 + length($marker) > $self->maxlen;

			my $hkeyword = lc($keyword);
			$hkeyword =~ s/[^\w]|_//ig;
			$hkeyword = $marker.$hkeyword;

			my $found_in_parts = 0;

			if (!$self->hashtags_at_end) {
				for (@parts) {
					next if ref $_ eq 'SCALAR';
					my $original_part = $_;
					$_ =~ s/($keyword)/$marker$1/i;
					if ($_ ne $original_part) {
						$found_in_parts = 1;
						last;
					}
				}
			}

			if ($self->hashtags_at_end || ( !$self->hashtags_at_end && !$found_in_parts ) ) {
				if ($count + 1 + length($hkeyword) <= $self->maxlen) {
					push @newparts, $hkeyword;
				}
			}

		}

	}
	for (@parts) { $_ = ${$_} if (ref $_ eq 'SCALAR') };
	push @parts, @newparts;

	return join(" ",@parts);
}



1;

__END__