File Coverage

blib/lib/Text/Snippet.pm

Criterion	Covered	Total	%
statement	61	62	98.3
branch	9	12	75.0
condition	1	2	50.0
subroutine	16	16	100.0
pod	3	3	100.0
total	90	95	94.7

package Text::Snippet;
BEGIN {
  $Text::Snippet::VERSION = '0.04';
}

# ABSTRACT: TextMate-like snippet functionality

use warnings;
use strict;
use Text::Balanced qw(extract_bracketed extract_multiple);
use Text::Snippet::TabStop::Parser;
use Text::Snippet::TabStop::Cursor;
use Scalar::Util qw(blessed);
use Carp qw(croak);


sub _new {
	my $class = shift;
	my $args = ref($_[0]) ? shift : {@_};
	my $self = {
		chunks    => [],
		tab_stops => [],
		%$args
	};
	croak "no src attribute specified" unless defined($self->{src});
	return bless $self, $class;
}
sub parse {
	my $class  = shift;
	my $source = shift;
	my @raw    = extract_multiple( $source, [ { Simple => qr/\$\d+/ },
			{ Curly  => sub { extract_bracketed( $_[0], '{}', '\$(?=\{\d)' ) } },
			{ Plain  => qr/[^\$]+/ },
	], undef, 1);

	my %tab_stop_cache;
	my @chunks;
	foreach my $c (@raw) {
		if ( ref($c) eq 'Plain' ) {
			push( @chunks, $$c );
		} else {

			# the leading $ gets stripped on these by extract_bracketed...
			$$c = '$' . $$c if(ref($c) eq 'Curly');

			my $t = Text::Snippet::TabStop::Parser->parse( $$c );

			if ( exists( $tab_stop_cache{ $t->index } ) ) {
				$t->parent($tab_stop_cache{ $t->index });
			} else {
				$tab_stop_cache{ $t->index } = $t;
			}
			push( @chunks, $t );
		}
	}

	my @tab_stops = map { $tab_stop_cache{$_} } sort { $a <=> $b } keys %tab_stop_cache;

	if ( exists( $tab_stop_cache{'0'} ) ) {
		# put the zero-th tab stop on the end of the array
		push( @tab_stops, shift(@tab_stops) );
	} else {
		# append the implicit zero-th tab stop on the end of the array
		my $implicit = Text::Snippet::TabStop::Parser->parse( '$0' );
		push( @tab_stops, $implicit );
		push( @chunks,       $implicit );
	}

	my %params = (
		src       => $source,
		chunks    => \@chunks,
		tab_stops => \@tab_stops,
	);
	return $class->_new(%params);
}



use overload '""' => sub { shift->to_string }, fallback => 1;

sub to_string {
	my $self = shift;
	return join( '', @{ $self->chunks } ) || '';
}

use Class::XSAccessor getters => { src => 'src', tab_stops => 'tab_stops', chunks => 'chunks' };


sub cursor {
	my $self = shift;
	return Text::Snippet::TabStop::Cursor->new( snippet => $self );
}


1;

__END__