File Coverage

blib/lib/Text/NumericData/Stat.pm

Criterion	Covered	Total	%
statement	42	43	97.6
branch	7	12	58.3
condition			n/a
subroutine	3	3	100.0
pod	0	1	0.0
total	52	59	88.1

package Text::NumericData::Stat;

# TODO: Integrate into Text::NumericData::File already.
# Also, return something for single data sets; just set non-computable measures to something invalid.

use Text::NumericData::File;

use strict;

# This is just a placeholder because of a past build system bug.
# The one and only version for Text::NumericData is kept in
# the Text::NumericData module itself.
our $VERSION = '1';
$VERSION = eval $VERSION;

# Generate a statistics file out of given input file.
# Gives and takes Text::NumericData::File objects.
# This could be a method of Text::NumericData::File, but it doesn't have to.
sub generate
{
	my $in = shift;
	my $out = Text::NumericData::File->new($in->{config});
	my @mean;  # arithmetic mean
	my @error; # standard error, sqrt(mean sq. error / N-1)
	my @min; # minimal value
	my @max; # maximal value

	$out->{title} = 'Statistics';
	$out->{title} .= ' of '.$in->{title} if defined $in->{title};
	$out->{titles} = ['column', 'name', 'mean', 'stderr', 'min', 'max'];

	my $N = @{$in->{data}};
	return $out if $N < 1;
	my $S = @{$in->{data}[0]};

	for my $i (0 .. $S-1)
	{
		$max[$i] = $min[$i] = $mean[$i] = $in->{data}[0][$i];
	}
	for(my $j=1; $j<@{$in->{data}}; ++$j)
	{
		my $d = $in->{data}[$j];
		for my $i (0 .. $S-1)
		{
			$mean[$i] += $d->[$i];
			$min[$i] = $d->[$i] if $d->[$i] < $min[$i];
			$max[$i] = $d->[$i] if $d->[$i] > $max[$i];
		}
	}
	for my $i (0 .. $S-1)
	{
		$mean[$i] /= $N;
	}
	for my $d (@{$in->{data}})
	{
		for my $i (0 .. $S-1)
		{
			$error[$i] += ($d->[$i]-$mean[$i])**2;
		}
	}
	for my $i (0 .. $S-1)
	{
		$error[$i] = $N > 1 ? sqrt($error[$i]/($N-1)) : 0;
	}
	for my $s (1 .. $S)
	{
		my $name = $in->{titles}[$s-1];
		if(defined $name)
		{
			$out->filter_text($name); # play safe since there is no quoting in data (yet?)
		}
		else
		{
			$name = "col$s";
		}
		$out->{data}[$s-1] = [ $s, $name, $mean[$s-1], $error[$s-1], $min[$s-1], $max[$s-1] ];
	}
	return $out;
}

1;

__END__