File Coverage

blib/lib/Text/Markdown/Slidy.pm

Criterion	Covered	Total	%
statement	71	75	94.6
branch	20	26	76.9
condition	12	17	70.5
subroutine	13	13	100.0
pod	3	5	60.0
total	119	136	87.5

package Text::Markdown::Slidy;
use 5.008001;
use strict;
use warnings;

use YAML::PP ();

our $VERSION = "0.04";
use parent 'Exporter';

our @EXPORT = qw/markdown split_markdown/;

sub new {
    my $class = shift;
    my %args = @_ == 1 ? %{$_[0]} : @_;
    bless {%args}, $class;
}

sub markdown {
    my ($self, $text) = @_;

    # Detect functional mode, and create an instance for this run
    unless (ref $self) {
        if ( $self ne __PACKAGE__ ) {
            my $ob = __PACKAGE__->new();
                                # $self is text, $text is options
            return $ob->markdown($self, $text);
        }
        else {
            croak('Calling ' . $self . '->markdown (as a class method) is not supported.');
        }
    }
    my ($body, $meta) = _separate_frontmater($text);
    my @slides = $self->_sections($body);
    my $html = join "\n", @slides;
    return wantarray ? ($html, $meta) : $html;
}

sub template {
    my $self = shift;

    $self->{template} ||= qq[\n%s\n];
}

sub _separate_frontmater {
    my $text = shift;

    my $delim = "---\n";
    my $strict_frontmatter;
    my ($raw_header, $body, $body2) = split /^$delim/ms, $text, 3;
    if ($raw_header eq '') {
        my $strict_frontmatter = 1;
        ($raw_header, $body) = ($body, $body2);
    } elsif ($body2) {
        $body = $body . $delim . $body2;
    }
    my $meta;
    if (!$body) {
        $body = $raw_header;
    } else {
        eval {
            $meta = YAML::PP::Load($raw_header);
        };
        if ($@ || !$meta || ref $meta ne 'HASH') {
            if ($strict_frontmatter) {
                die sprintf("invalid frontmatter\n%s", $raw_header);
            }
            undef $meta;
            $body = $raw_header . $delim . $body;
        }
    }
    return ($body, $meta);
}

sub md {
    my $self = shift;

    $self->{md} ||= do {
        require Text::Markdown;
        Text::Markdown->new;
    };
}

sub _process {
    my ($self, $slide_text) = @_;

    my $html  = $self->md->markdown($slide_text);
    sprintf $self->template, $html;
}

sub _sections {
    my ($self, $text) = @_;

    map {$self->_process($_)} split_markdown($text);
}

sub split_markdown {
    my $text = shift;
    $text =~ s/^\A\s+//ms;
    $text =~ s/\s+\z//ms;

    my @slides;
    my @slide_lines;
    for my $line (split /\r?\n/, $text) {
        if ( my ($delim) = $line =~ /^([- ]+?|=+)\s*$/ and @slide_lines) {
            if ($delim =~ / / || !$slide_lines[$#slide_lines]) {
                #
                # `- - -`
                # "\n\n----\n"
                push @slides, join("\n", (@slide_lines, $line));
                @slide_lines = ();
                next;
            }
            # h1 or h2
            my $prev = pop @slide_lines;
            push @slides, join("\n", @slide_lines) if @slide_lines;
            @slide_lines = ($prev); # $prev is title;
        }
        push @slide_lines, $line;
    }
    push @slides, join("\n", @slide_lines) if @slide_lines;

    @slides;
}

1;
__END__