File Coverage

blib/lib/Text/Hunspell/FFI.pm

Criterion	Covered	Total	%
statement	31	31	100.0
branch	5	6	83.3
condition			n/a
subroutine	8	8	100.0
pod			n/a
total	44	45	97.7

package Text::Hunspell::FFI;

use strict;
use warnings;
use 5.020;
use FFI::Platypus;
use Text::Hunspell::FFI::Lib;
use experimental qw( postderef );

# ABSTRACT: Perl FFI interface to the Hunspell library
our $VERSION = '0.02'; # VERSION

sub _ffi
{
  state $ffi;

  unless(defined $ffi)
  {
    my @libs = Text::Hunspell::FFI::Lib::_libs();

    die "unable to find libs" unless @libs;

    $ffi = FFI::Platypus->new(
      lib => \@libs,
    );
    $ffi->load_custom_type('::StringArray' => 'string_array');
  }

  $ffi;
}

_ffi->attach(['Hunspell_create'=>'new'] => ['string','string'] => 'opaque', sub
{
  my($xsub, $class, $aff, $dic) = @_;
  my $ptr = $xsub->($aff, $dic);
  bless \$ptr, $class;
});


_ffi->attach(['Hunspell_destroy'=>'DESTROY'] => ['opaque'] => 'void', sub
{
  my($xsub, $self) = @_;
  $xsub->($$self);
});

foreach my $try (qw( Hunspell_add_dic _ZN8Hunspell7add_dicEPKcS1_ ))
{
  eval {
    _ffi->attach([$try=>'add_dic'] => ['opaque','string'] => 'void', sub
    {
      my($xsub, $self, $dpath) = @_;
      $xsub->($$self, $dpath);
    });
  };
  last unless $@;
}

unless(__PACKAGE__->can('add_dic'))
{
  # TODO: fallback on Perl implementation ?
  die "unable to find add_dic";
}

_ffi->attach(['Hunspell_spell'=>'check'] => ['opaque','string'] => 'int', sub
{
  my($xsub, $self, $word) = @_;
  $xsub->($$self, $word);
});

_ffi->attach(['Hunspell_free_list',=>'_free_list'] => ['opaque','opaque*','int'] => 'void');

sub _string_array_and_word
{
  my($xsub, $self, $word) = @_;
  my $ptr;
  my $count = $xsub->($$self, \$ptr, $word);
  my @result = map { _ffi->cast('opaque','string',$_) } _ffi->cast('opaque',"opaque[$count]", $ptr)->@*;
  _free_list($self, $ptr, $count);
  wantarray ? @result : $result[0];
}

_ffi->attach(['Hunspell_suggest'=>'suggest'] => ['opaque','opaque*','string'] => 'int', \&_string_array_and_word);
_ffi->attach(['Hunspell_analyze'=>'analyze'] => ['opaque','opaque*','string'] => 'int', \&_string_array_and_word);

_ffi->attach(['Hunspell_generate'=>'generate'] => ['opaque','opaque*','string','string'] => 'int', sub {
  my($xsub, $self, $word, $word2) = @_;
  my $ptr;
  my $count = $xsub->($$self, \$ptr, $word, $word2);
  my @result = map { _ffi->cast('opaque','string',$_) } _ffi->cast('opaque',"opaque[$count]", $ptr)->@*;
  _free_list($self, $ptr, $count);
  wantarray ? @result : $result[0];
});

_ffi->attach(['Hunspell_generate2'=>'generate2'] => ['opaque','opaque*','string','string_array','int'] => 'int', sub
{
  my($xsub, $self, $word, $suggestions) = @_;
  my $n = scalar @$suggestions;
  my $ptr;
  my $count = $xsub->($$self, \$ptr, $word, [@$suggestions], 1);
  my @result = map { _ffi->cast('opaque','string',$_) } _ffi->cast('opaque',"opaque[$count]", $ptr)->@*;
  _free_list($self, $ptr, $count);
  wantarray ? @result : $result[0];
});

1;

__END__