File Coverage

blib/lib/Text/Graph/DataSet.pm

Criterion	Covered	Total	%
statement	50	50	100.0
branch	22	22	100.0
condition	7	9	77.7
subroutine	7	7	100.0
pod	0	1	0.0
total	86	89	96.6

package Text::Graph::DataSet;

use strict;
use warnings;
use Moo;
use namespace::clean;

our $VERSION = '0.83';

has values => (
    is     => 'ro',
    reader => 'get_values',
);
has labels => (
    is     => 'ro',
    reader => 'get_labels',
);

#
# This routine is quite complicated to support the bizarre interface that I
# originally supported.
sub BUILDARGS
{
    my ( $class, @args ) = @_;
    return { values => [], labels => [] } if !@args;
    my ( $values, $labels, $hash ) = ( [], undef, undef );

    if( ref $args[0] eq ref [] )
    {
        $values = shift @args;
        if( ref $args[0] eq ref [] )
        {
            $labels = shift @args;
        }
    }
    elsif( ref $args[0] eq ref {} )
    {
        $hash = shift @args;
        if( ref $args[0] eq ref [] )
        {
            $labels = shift @args;
        }
    }
    die "Odd number of parameters to new.\n" if @args % 2 == 1;
    my %real_args = ( sort => sub { sort @_ }, @args );
    my $sortref = delete $real_args{sort};
    $hash ||= delete $real_args{hash};
    if( defined $hash )
    {
        if( $sortref )
        {
            my ( $pkg ) = caller;
            $labels ||= [ $sortref->( keys %{$hash} ) ] if !$labels;
        }
        else
        {
            $labels ||= [ keys %{$hash} ];
        }
        $values = [ @{$hash}{ @{$labels} } ];
        $hash   = undef;
    }
    $labels ||= [];
    push @{$labels}, ( '' ) x ( @{$values} - @{$labels} ) if @{$values} > @{$labels};
    return { values => $values, labels => $labels, %real_args };
}

#
# Support the list or array ref original interface.
sub _list_or_ref
{
    my ( $orig, $self ) = @_;
    my $val = $orig->( $self );
    return wantarray ? @{$val} : $val;
}

around 'get_values' => \&_list_or_ref;
around 'get_labels' => \&_list_or_ref;

1;
__END__