File Coverage

blib/lib/Text/Graph/DataSet.pm

Criterion	Covered	Total	%
statement	48	48	100.0
branch	26	26	100.0
condition			n/a
subroutine	7	7	100.0
pod	3	3	100.0
total	84	84	100.0

package Text::Graph::DataSet;

use strict;
use warnings;

our $VERSION = '0.50';

sub new
{
    my $class = shift;
    my $obj   = {
        values => [],
        labels => undef,
        hash   => undef,
        sort   => sub { sort @_ }
    };

    if( @_ )
    {
        if( 'ARRAY' eq ref $_[0] )
        {
            $obj->{values} = shift;
        }
        elsif( 'HASH' eq ref $_[0] )
        {
            $obj->{hash} = shift;
        }
        $obj->{labels} = shift if 'ARRAY' eq ref $_[0];
    }

    if( @_ )
    {
        die "Odd number of parameters to new.\n" unless 0 == ( @_ % 2 );
        $obj = { %{$obj}, @_ };
    }

    $obj = bless $obj, $class;

    $obj->_initialize();

    return $obj;
}

sub get_values
{
    my $self = shift;

    return wantarray ? @{ $self->{values} } : $self->{values};
}

sub get_labels
{
    my $self = shift;

    return wantarray ? @{ $self->{labels} } : $self->{labels};
}

sub _initialize
{
    my $self = shift;

    if( defined $self->{hash} )
    {
        unless( defined $self->{labels} )
        {
            if( defined $self->{sort} )
            {
                $self->{labels} = [ $self->{sort}->( keys %{ $self->{hash} } ) ];
            }
            else
            {
                $self->{labels} = [ keys %{ $self->{hash} } ];
            }
        }

        $self->{values} = [ @{ $self->{hash} }{ @{ $self->{labels} } } ];
    }
    elsif( !defined $self->{labels} )
    {
        $self->{labels} = [ ( '' ) x scalar( @{ $self->{values} } ) ];
    }

    if( scalar @{ $self->{values} } > scalar @{ $self->{labels} } )
    {
        push @{ $self->{labels} },
            ( '' ) x ( scalar @{ $self->{values} } - scalar @{ $self->{labels} } );
    }
    return;
}

1;
__END__