File Coverage

lib/Text/Frundis.pm

Criterion	Covered	Total	%
statement	47	59	79.6
branch	12	22	54.5
condition	21	38	55.2
subroutine	11	11	100.0
pod	3	4	75.0
total	94	134	70.1

# Copyright (c) 2014, 2015 Yon
#
# Permission to use, copy, modify, and distribute this software for any
# purpose with or without fee is hereby granted, provided that the above
# copyright notice and this permission notice appear in all copies.
#
# THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
# WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
# MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
# ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
# WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
# ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
# OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
#
# vim:sw=4:sts=4:expandtab

package Text::Frundis;

# as in the perlunicook
use utf8;
use v5.12;
use strict;
use warnings;
use open qw(:std :utf8);

use Text::Frundis::Processing;
use Carp;

our $VERSION = "2.14";

sub new {
    my $class = shift;
    my $self  = {};
    bless $self, $class;
}

sub process_source {
    my ($self, %opts) = @_;

    $opts{use_carp} //= 1;
    croak("`target_format' parameter required")
      unless defined $opts{target_format}
      or $opts{script};
    carp(
        "`all_in_one_file' parameter doesn't make sense when exporting to epub")
      unless $opts{script}
      or not($opts{all_in_one_file} and $opts{target_format} eq "epub");
    if (    not $opts{script}
        and $opts{target_format} eq "epub"
        and not defined $opts{output_file})
    {
        croak "when exporting to epub the ``output_file'' parameter is mandatory";
    }
    if (    not $opts{script}
        and $opts{target_format} eq "xhtml"
        and not $opts{all_in_one_file}
        and not defined $opts{output_file})
    {
        croak "when exporting to xhtml, unless ``all_in_one_file'' is specified, "
          . "``output_file'' is mandatory";
    }

    my $macros = $self->{macros};
    if (defined $macros) {
        foreach my $macro (keys %$macros) {
            $opts{user_macros}{$macro} = {
                perl => 1,
                lnum => 0,
                code => $macros->{$macro},
            };
        }
    }
    my $filters = $self->{filters};
    if (defined $filters) {
        foreach my $filter (keys %$filters) {
            $opts{filters}{$filter} = {
                code => $filters->{$filter},
            };
        }
    }

    Text::Frundis::Processing::process_frundis_source(\%opts);
}

sub add_macro {
    my ($self, $macro, $code) = @_;

    unless (defined $macro and $macro ne "") {
        carp "undefined macro name";
        return;
    }
    if ($macro =~ /\s/) {
        carp "macro name should not contain spaces";
        return;
    }
    unless (defined $code and ref($code) eq "CODE") {
        carp "a coderef is required";
        return;
    }

    $self->{macros}{$macro} = $code;
}

sub add_filter {
    my ($self, $tag, $code) = @_;

    unless (defined $tag and $tag ne "") {
        carp "undefined tag name";
        return;
    }
    unless (defined $code and ref($code) eq "CODE") {
        carp "a coderef is required";
        return;
    }

    $self->{filters}{$tag} = $code;
}

1;

__END__