File Coverage

blib/lib/Text/Clevery.pm

Criterion	Covered	Total	%
statement	50	56	89.2
branch	1	2	50.0
condition	5	6	83.3
subroutine	16	18	88.8
pod	2	6	33.3
total	74	88	84.0

package Text::Clevery;

use 5.008_001;
use strict;
use warnings;

our $VERSION = '0.0004';

sub smarty_compatible_version { '2.6' }

use parent qw(Text::Xslate);

use Carp ();

use Text::Xslate::Util qw(p);
use Text::Clevery::Context;
use Text::Clevery::Function;
use Text::Clevery::Modifier;

my %builtin = (
    '@clevery_context'              => \&get_current_context,
    '@clevery_set_foreach_property' => \&_set_foreach_property,
    '@clevery_array_is_not_empty'   => \&_array_is_not_empty,
    '@clevery_not_implemented'      => \&_not_implemented,
    Text::Clevery::Function->methods(),
    Text::Clevery::Modifier->methods(),
);

sub default_functions { \%builtin }

sub options {
    my($self) = @_;

    my $opts = $self->SUPER::options;

    $opts->{syntax} = 'Text::Clevery::Parser';

    # set delimiters here to make access easier
    $opts->{tag_start} = '{';
    $opts->{tag_end}   = '}';
    return $opts;
}

sub render_string {
    my($self, $str, $vars, @args) = @_;

    local $self->{clevery_context_args} = \@args;
    local $self->{clevery_context};
    return $self->SUPER::render_string($str, $vars);
}

sub render {
    my($self, $str, $vars, @args) = @_;

    local $self->{clevery_context_args} = \@args;
    local $self->{clevery_context};
    return $self->SUPER::render($str, $vars);
}

sub get_current_context {
    my $self = __PACKAGE__->current_engine()
        or Carp::confess("Cannot get clevery context outside render()");
    return $self->{clevery_context} ||= Text::Clevery::Context->new(
            @{$self->{clevery_context_args}},
            _engine => $self,
        );
}

sub _set_foreach_property {
    my($name, $index, $body) = @_;

    my $context = get_current_context();

    my $size = scalar @{$body};
    $context->foreach->{$name} = {
        index => $index,
        iteration => $index + 1,
        first     => $index == 0,
        last      => $index == ($size - 1),
        show      => undef, # ???
        total     => $size,
    };
    return;
}

sub _array_is_not_empty {
    my($arrayref) = @_;
    return defined($arrayref) && @{$arrayref} != 0;
}

sub _not_implemented {
    my($name) = @_;
    die "NotImplemented: $name\n";
}

1;
__END__