File Coverage

blib/lib/Text/CSV_Multiline.pm

Criterion	Covered	Total	%
statement	36	48	75.0
branch	6	12	50.0
condition	1	6	16.6
subroutine	6	8	75.0
pod	0	4	0.0
total	49	78	62.8

package Text::CSV_Multiline;

use strict;
use warnings;

use base "Exporter";
use Fcntl ":seek";

our @EXPORT = qw(
	csv_quote
	csv_unquote
	csv_read_record
	csv_write_record
);

our $VERSION = 0.01;
our $ALWAYS_USE_QUOTES = 0;

sub csv_quote
{
	my $value = shift;
	$value = "" if not defined $value;
	if ($value =~ /^[\w\d.]*$/s && !$ALWAYS_USE_QUOTES)
	{
		return $value;
	}
	$value =~ s/"/""/gs;
	return "\"$value\"";
}

sub csv_unquote
{
	my $quoted = shift;
	$quoted =~ s/^\s+//s;
	$quoted =~ s/\s+$//s;
	if ($quoted =~ /^"(.*)"$/s)
	{
		$quoted = $1;
		$quoted =~ s/""/"/gs;
	}
	#print STDERR "found field: >$quoted<\n";
	return $quoted;
}

sub csv_read_record
{
	my $fh = shift;
	my @parts = ();
	my $line = "";
	my $num_lines = 0;
	local $_;
	while (defined($_ = (ref($fh) && $fh->can("readline"))? $fh->readline : <$fh>))
	{
		$line .= $_;
		my $quoted_field = qr/"(?:[^"]|"")*"/;
		my $unquoted_field = qr/[^,"]*/;
		my $field = qr/\s*(?:$quoted_field|$unquoted_field)\s*/;

		while ($line =~ s/^($field),//s)
		{
			push @parts, csv_unquote($1);
		}

		if ($line =~ /^($field)$/s)
		{
			# last field
			push @parts, csv_unquote($1);
			return @parts;
		}
	}
	if (length($line))
	{
		warn "detected eof before last field was finished\n";
		warn "-->$line<--\n";
	}
	return @parts;
}

sub csv_write_record
{
	my $fh = shift;
	my @values = @_;
	print $fh join(",", map { csv_quote($_) } @values) . "\n";
}

1;
__END__