File Coverage

blib/lib/Text/CSV/R/Matrix.pm

Criterion	Covered	Total	%
statement	58	62	93.5
branch	13	16	81.2
condition	6	6	100.0
subroutine	14	15	93.3
pod	2	2	100.0
total	93	101	92.0

package Text::CSV::R::Matrix;

require 5.005;

use strict;
use warnings;

use Carp;
use Tie::Array;
use Scalar::Util qw(reftype looks_like_number);

our @ISA = 'Tie::Array';

our $VERSION = '0.3';

sub TIEARRAY {
    my ($self) = @_;
    return bless { ARRAY => [], ROWNAMES => [], COLNAMES => [], }, $self;
}

sub FETCH {
    my ( $self, $index ) = @_;
    return $self->{ARRAY}->[$index];
}

sub STORE {
    my ( $self, $index, $value ) = @_;
    $self->{ARRAY}->[$index] = $value;
    return;
}

sub FETCHSIZE {
    my $self = shift;
    return scalar @{ $self->{ARRAY} };
}

sub STORESIZE {
    my ( $self, $value ) = @_;
    $#{ $self->{ARRAY} }    = $value - 1;
    $#{ $self->{ROWNAMES} } = $value - 1;
    return;
}

sub EXTEND {
    my ( $self, $count ) = @_;
    $self->STORESIZE($count);
    return;
}

sub SPLICE {
    my $ob  = shift;
    my $sz  = $ob->FETCHSIZE;
    my $off = @_ ? shift : 0;
    if ( $off < 0 ) {
        $off += $sz;
    }
    my $len = @_ ? shift : $sz - $off;

    # if LIST provided, empty new ROWNAMES
    my @rn = map {q{}} @_;
    splice @{ $ob->{ROWNAMES} }, $off, $len, @rn;
    return splice @{ $ob->{ARRAY} }, $off, $len, @_;
}

sub COLNAMES {
    my ( $self, $values ) = @_;
    if ( defined $values ) {
        if ( !_is_array_ref($values) ) {
            croak 'Invalid colnames length';
        }
        $self->{COLNAMES} = $values;
    }
    return $self->{COLNAMES};
}

sub ROWNAMES {
    my ( $self, $values ) = @_;
    if ( defined $values ) {
        if ( !_is_array_ref($values)
            || scalar @{$values} != scalar @{ $self->{ARRAY} } )
        {
            croak 'Invalid rownames length';
        }
        $self->{ROWNAMES} = $values;
    }
    return $self->{ROWNAMES};
}

sub _is_array_ref {
    my ($values) = @_;
    return ( defined reftype $values && reftype $values eq 'ARRAY' ) ? 1 : 0;
}

1;
__END__