File Coverage

blib/lib/Text/BlockLayout.pm

Criterion	Covered	Total	%
statement	39	39	100.0
branch	4	4	100.0
condition	10	12	83.3
subroutine	8	8	100.0
pod	1	3	33.3
total	62	66	93.9

package Text::BlockLayout;

use 5.010;
use strict;
use warnings;
use utf8;

our $VERSION = '0.03';

use Moo;

has max_width => (
    is          => 'rw',
    required    => 1,
);

has line_continuation_threshold => (
    is          => 'rw',
    default     => sub { int(shift->max_width * 2 / 3 + 0.5) },
    lazy        => 1,
);
has separator => (
    is      => 'rw',
    default => sub { ' ' },
);

has wrapper    => (
    is       => 'rw',
    lazy        => 1,
    default  => sub {
        return sub {
            my ($max_width, $text) = @_;
            require Text::Wrapper;
            my $wrapper = Text::Wrapper->new(columns => $max_width);
            $wrapper->wrap($text);
        };
    },
);

has wrap_predefined_lines => (
    is          => 'rw',
    default     => sub { 1 },
);

sub add_text {
    my ($self, @chunks) = @_;

    push @{$self->{chunks}}, map [0, $_], @chunks;
    $self;
}

sub add_line {
    my ($self, @chunks) = @_;

    push @{$self->{chunks}}, map [1, $_], @chunks;
    $self;
}

sub formatted {
    my $self = shift;

    my @lines;
    my $last_line_separate = 0;
    for my $chunk ( @{ $self->{chunks} }) {
        my ($separate_line, $text) = @$chunk;
        my $start_new_line   = $last_line_separate || $separate_line || !@lines;
           $start_new_line ||= length($lines[-1]) > $self->line_continuation_threshold;
           $start_new_line ||= (length($lines[-1]) + length($self->separator) + length $text) > $self->max_width;
        if ($start_new_line) {
            if (!$separate_line || $self->wrap_predefined_lines) {
                push @lines, split /\n/, $self->wrapper->($self->max_width, $text);
            }
            else {
                push @lines, split /\n/, $text;
            }
        }
        else {
            $lines[-1] .= $self->separator . $text;
        }
        $last_line_separate = $separate_line;
    }
    return join "\n", @lines, '';
}


1;

__END__