File Coverage

blib/lib/Text/Annotated/Reader.pm

Criterion	Covered	Total	%
statement	7	9	77.7
branch			n/a
condition			n/a
subroutine	3	3	100.0
pod			n/a
total	10	12	83.3

package Text::Annotated::Reader;
# $Id: Reader.pm,v 1.7 2007-05-12 18:39:16 wim Exp $
use strict;
use vars qw($VERSION);
use Text::Filter;
use Text::Annotated::Line;
use base qw(Text::Filter);
$VERSION = '0.04';

sub new {
    my $proto = shift;
    my $pkg = ref($proto) || $proto;
    my $this = $pkg->SUPER::new(output => [], @_);
    bless $this, $pkg;
}

sub set_input { # overrides set_input of Text::Filter, adds a type check
    my ($this,$input,$postread) = @_;

    # the input needs to be specified as a filename
    !ref($input) or
	die "Invalid input specified.\n"
          . "Text::Annotated::Reader expects a filename,\n"
	  . "stopped";

    $this->SUPER::set_input($input,$postread);
}

sub set_output { # overrides set_output of Text::Filter, adds some magic
    my ($this,$output,$prewrite) = @_;

    # the output needs to be a ref to an array
    ref($output) eq 'ARRAY' or
	die "Invalid output. Text::Annotated::Writer expects a ref to an array,\n"
          . "stopped";

    # construct a magic handler which actually annotates the lines
    my $linenr = 1; # index of first line
    my $magic_handler = sub {
	my $line = new Text::Annotated::Line(
            filename => $this->{input},
            linenr   => $linenr++,
	    content  => $_[0],
        );
	push @$output, $line;
    };

    # keep the array in a separate field
    $this->{annotated_lines} = $output;

    $this->SUPER::set_output($magic_handler,$prewrite);
}

sub read { # reads and annotates an entire file
    my Text::Annotated::Reader $this = shift;

    # autogenerate an output array if no output is specified
    $this->set_output([]) unless defined $this->{annotated_lines};

    # copy the lines from input to output, letting the output handler
    # do the annotation
    while(defined(my $line = $this->readline())) {
	$this->writeline($line);
    }
}

sub run { # needed when using the filter in a Text::Filter::Chain
    my $this = shift;
    $this->read(@_);
    return wantarray ? @{$this->{annotated_lines}} : $this->{annotated_lines};
}

sub reader { # constructs and runs a filter
    my $proto = shift;
    my $this = $proto->new(@_);
    $this->read;
    return $this;
}

1;

__END__