File Coverage

blib/lib/Text/Abbreviate.pm

Criterion	Covered	Total	%
statement	39	39	100.0
branch	10	14	71.4
condition	3	8	37.5
subroutine	7	7	100.0
pod	0	4	0.0
total	59	72	81.9

package Text::Abbreviate;

use 5.006;
use strict;
use warnings;

our $VERSION = '0.01';


sub new {
  my $class = shift;
  my $self = bless {}, $class;

  $self->{opts} = shift
    if @_ and ref($_[0]) and ref($_[0]) eq "HASH";
  $self->{words} = [map { $_->[0] } sort { $a->[1] cmp $b->[1] } map { [$_, lc] } @_];
  $self->{string} = join("\n", @{ $self->{words} }) . "\n";
  $self->{cache} = {};

  return $self;
}


sub expand {
  my ($self, $word) = @_;
  my $i = $self->{opts}{fold} ? "(?i)" : "";
  my $m = ($self->{cache}{$i}{$word} ||= [ $self->{string} =~ /^($i\Q$word\E.*)\n/mg ]);
  return wantarray ? @$m : $m;
}


sub unambiguous {
  my ($self) = @_;
  my $i = $self->{opts}{fold} ? "(?i)" : "";
  my %abbr;

  WORD: for my $word (@{ $self->{words} }) {
    my $len = length $word;
    my $l = 0;

    while (++$l < $len) {
      my $w = substr $word, 0, $l;
      last if $self->{string} !~ /^$i\Q$w\E.*\n\Q$w\E/m;
    }

    $abbr{$word} = [map substr($word, 0, $_), $l .. $len];
  }

  return wantarray ? %abbr : \%abbr;
}


sub folding {
  my $self = shift;
  return $self->{opts}{fold} unless @_;
  $self->{opts}{fold} = shift;
}


1;

__END__