File Coverage

blib/lib/Test2/Tools/HTTP/UA/LWPClass.pm

Criterion	Covered	Total	%
statement	40	43	93.0
branch	5	8	62.5
condition	4	12	33.3
subroutine	10	10	100.0
pod	0	2	0.0
total	59	75	78.6

package Test2::Tools::HTTP::UA::LWPClass;

use strict;
use warnings;
use URI;
use parent 'Test2::Tools::HTTP::UA';

# ABSTRACT: Global LWP user agent wrapper for Test2::Tools::HTTP
our $VERSION = '0.11'; # VERSION


my %orig;
my $ua;

sub instrument
{
  my($self) = @_;

  require LWP::Protocol;
  require LWP::UserAgent;

  foreach my $proto (qw( http https ))
  {
    $orig{$proto} ||= do {
      my $orig = LWP::Protocol::implementor($proto);
      LWP::Protocol::implementor($proto, 'Test2::Tools::HTTP::UA::LWPClass::Proto');
      $orig;
    };
  }

  $ua ||= LWP::UserAgent->new;
}

sub request
{
  my($self, $req, %options) = @_;

  if($self->apps->uri_to_app($req->uri) && $req->uri =~ /^\//)
  {
    $req->uri(
      URI->new_abs($req->uri, $self->apps->base_url),
    );
  }

  my $res = $options{follow_redirects}
    ? $ua->request($req)
    : $ua->simple_request($req);

  if(my $warning = $res->header('Client-Warning'))
  {
    $self->error(
      "connection error: " . ($res->decoded_content || $warning),
      $res,
    );
  }

  $res;
}

__PACKAGE__->register('LWP::UserAgent', 'class');

package Test2::Tools::HTTP::UA::LWPClass::Proto;

use parent qw(LWP::Protocol);
use HTTP::Message::PSGI qw( req_to_psgi res_from_psgi );

sub apps { Test2::Tools::HTTP::UA->apps }

sub request
{
  my($self, $req, $proxy, $arg, @rest) = @_;

  if(my $app = $self->apps->uri_to_app($req->uri))
  {
    my $env = req_to_psgi $req;
    my $res = res_from_psgi $app->($env);
    my $content = $res->content;
    $res->content('');
    return $self->collect_once($arg, $res, $content);
  }
  else
  {
    return $orig{$self->{scheme}}->new($self->{scheme}, $self->{ua})->request($req, $proxy, $arg, @rest);
  }
}

1;

__END__