File Coverage

blib/lib/Test2/Tools/Target.pm

Criterion	Covered	Total	%
statement	39	42	92.8
branch	5	8	62.5
condition	1	2	50.0
subroutine	7	8	87.5
pod	0	1	0.0
total	52	61	85.2

package Test2::Tools::Target;
use strict;
use warnings;

our $VERSION = '0.000155';

use Carp qw/croak/;

use Test2::Util qw/pkg_to_file/;

sub import {
    my $class = shift;

    my $caller = caller;
    $class->import_into($caller, @_);
}

sub import_into {
    my $class = shift;
    my $into = shift or croak "no destination package provided";

    croak "No targets specified" unless @_;

    my %targets;
    if (@_ == 1) {
        if (ref $_[0] eq 'HASH') {
            %targets = %{ $_[0] };
        }
        else {
            ($targets{CLASS}) = @_;
        }
    }
    else {
        %targets = @_;
    }

    for my $name (keys %targets) {
        my $target = $targets{$name};

        my $file = pkg_to_file($target);
        require $file;

        $name ||= 'CLASS';

        my $const;
        {
            my $const_target = "$target";
            $const = sub() { $const_target };
        }

        no strict 'refs';
        *{"$into\::$name"} = \$target;
        *{"$into\::$name"} = $const;
    }
}

1;

__END__