File Coverage

blib/lib/Test2/Plugin/ExitSummary.pm

Criterion	Covered	Total	%
statement	21	21	100.0
branch	12	12	100.0
condition	17	18	94.4
subroutine	6	6	100.0
pod	0	2	0.0
total	56	59	94.9

package Test2::Plugin::ExitSummary;
use strict;
use warnings;

our $VERSION = '0.000153';

use Test2::API qw/test2_add_callback_exit/;

my $ADDED_HOOK = 0;
sub import { test2_add_callback_exit(\&summary) unless $ADDED_HOOK++ }

sub active { $ADDED_HOOK }

sub summary {
    my ($ctx, $real, $new) = @_;

    # Avoid double-printing diagnostics if Test::Builder already loaded.
    return if $INC{'Test/Builder.pm'};

    my $hub    = $ctx->hub;
    my $plan   = $hub->plan;
    my $count  = $hub->count;
    my $failed = $hub->failed;

    $ctx->diag('No tests run!') if !$count && (!$plan || $plan ne 'SKIP');
    $ctx->diag('Tests were run but no plan was declared and done_testing() was not seen.')
        if $count && !$plan;

    $ctx->diag("Looks like your test exited with $real after test #$count.")
        if $real;

    $ctx->diag("Did not follow plan: expected $plan, ran $count.")
        if $plan && $plan =~ m/^[0-9]+$/ && defined $count && $count != $plan;
}

1;

__END__