File Coverage

blib/lib/Test2/Compare/Scalar.pm

Criterion	Covered	Total	%
statement	37	37	100.0
branch	10	10	100.0
condition	3	3	100.0
subroutine	11	11	100.0
pod	4	5	80.0
total	65	66	98.4

package Test2::Compare::Scalar;
use strict;
use warnings;

use base 'Test2::Compare::Base';

our $VERSION = '0.000153';

use Test2::Util::HashBase qw/item/;

use Carp qw/croak confess/;
use Scalar::Util qw/reftype blessed/;

sub init {
    my $self = shift;
    croak "'item' is a required attribute"
        unless defined $self->{+ITEM};

    $self->SUPER::init();
}

sub name     { '' }
sub operator { '${...}' }

sub verify {
    my $self = shift;
    my %params = @_;
    my ($got, $exists) = @params{qw/got exists/};

    return 0 unless $exists;
    return 0 unless defined $got;
    return 0 unless ref($got);
    return 0 unless reftype($got) eq 'SCALAR' || reftype($got) eq 'VSTRING';
    return 1;
}

sub deltas {
    my $self = shift;
    my %params = @_;
    my ($got, $convert, $seen) = @params{qw/got convert seen/};

    my $item = $self->{+ITEM};
    my $check = $convert->($item);

    return (
        $check->run(
            id      => ['SCALAR' => '$*'],
            got     => $$got,
            convert => $convert,
            seen    => $seen,
            exists  => 1,
        ),
    );
}

1;

__END__