File Coverage

blib/lib/Test2/Roo.pm

Criterion	Covered	Total	%
statement	50	50	100.0
branch	6	10	60.0
condition			n/a
subroutine	13	13	100.0
pod	3	3	100.0
total	72	76	94.7

use 5.008001;
use strictures;

package Test2::Roo;
# ABSTRACT: Composable, reusable tests with roles and Moo

our $VERSION = '1.005';

use Test2::API qw( context run_subtest );
use Sub::Install;

sub import {
    my ( $class, @args ) = @_;
    my $caller = caller;
    for my $sub (qw/test top_test run_me/) {
        Sub::Install::install_sub( { into => $caller, code => $sub } );
    }
    strictures->import; # do this for Moo, since we load Moo in eval
    eval qq{
        package $caller;
        use Moo;
        extends 'Test2::Roo::Class'
    };
    die $@ if $@;
    if (@args) {
        eval qq{ package $caller; use Test2::V0 \@args };
    }
    else {
        eval qq{ package $caller; use Test2::V0 };
    }
    die $@ if $@;
}

sub test {
    my ( $name, $code ) = @_;
    my $caller  = caller;
    my $subtest = sub {
        my $self = shift;
        my $ctx = context();
        my $pass = run_subtest( $name, sub { $self->each_test($code) }, { buffered => 1, inherit_trace => 1 } );
        $ctx->release;
        return $pass;
    };
    eval qq{ package $caller; after _do_tests => \$subtest };
    die $@ if $@;
}

sub top_test {
    my ( $name, $code ) = @_;
    my $caller = caller;
    my $test = sub { shift->each_test($code) };
    eval qq{ package $caller; after _do_tests => \$test };
    die $@ if $@;
}

sub run_me {
    my $class = caller;
    $class->run_tests(@_);
}

1;


# vim: ts=4 sts=4 sw=4 et:

__END__