File Coverage

blib/lib/Test2/Plugin/MemUsage.pm

Criterion	Covered	Total	%
statement	30	30	100.0
branch	9	18	50.0
condition			n/a
subroutine	6	6	100.0
pod	0	1	0.0
total	45	55	81.8

package Test2::Plugin::MemUsage;
use strict;
use warnings;

our $VERSION = '0.002003';

use Test2::API qw/test2_add_callback_exit/;

my $ADDED_HOOK = 0;

sub import {
    return if $ADDED_HOOK++;

    test2_add_callback_exit(\&send_mem_event);
}

sub proc_file { "/proc/$$/status" }

sub send_mem_event {
    my ($ctx, $real, $new) = @_;

    my $file = proc_file();
    return unless -f $file;

    my $stats;
    {
        open(my $fh, '<', $file) or die "Could not open file '$file' (<): $!";
        local $/;
        $stats = <$fh>;
        close($fh) or die "Could not close file '$file': $!";
    }

    return unless $stats;

    my %mem = (peak => ['NA', ''], size => ['NA', ''], rss  => ['NA', '']);
    $mem{peak} = [$1, $2] if $stats =~ m/VmPeak:\s+(\d+) (\S+)/;
    $mem{size} = [$1, $2] if $stats =~ m/VmSize:\s+(\d+) (\S+)/;
    $mem{rss}  = [$1, $2] if $stats =~ m/VmRSS:\s+(\d+) (\S+)/;

    return unless grep { $_[0] ne 'NA' } values %mem;

    $mem{details} = "rss:  $mem{rss}->[0]$mem{rss}->[1]\nsize: $mem{size}->[0]$mem{size}->[1]\npeak: $mem{peak}->[0]$mem{peak}->[1]";

    $ctx->send_ev2(
        memory => \%mem,
        about  => {package => __PACKAGE__, details => $mem{details}},
        info   => [{tag => 'MEMORY', details => $mem{details}}],

        harness_job_fields => [
            {name => 'mem_rss',  details => $mem{rss}->[0] . $mem{rss}->[1]},
            {name => 'mem_size', details => $mem{size}->[0] . $mem{size}->[1]},
            {name => 'mem_peak', details => $mem{peak}->[0] . $mem{peak}->[1]},
        ],
    );
}

1;

__END__