File Coverage

blib/lib/Test2/Plugin/IOMuxer.pm

Criterion	Covered	Total	%
statement	55	73	75.3
branch	6	24	25.0
condition	1	5	20.0
subroutine	14	15	93.3
pod	0	1	0.0
total	76	118	64.4

package Test2::Plugin::IOMuxer;
use strict;
use warnings;

our $VERSION = '0.000009';


use Test2::Plugin::OpenFixPerlIO;
use Test2::Plugin::IOMuxer::Layer;
use Test2::Plugin::IOMuxer::STDERR;
use Test2::Plugin::IOMuxer::STDOUT;
use Test2::Plugin::IOMuxer::FORMAT;

use IO::Handle;

use Test2::API qw{
    test2_add_callback_post_load
    test2_stack
};

use Carp qw/confess/;

our @EXPORT_OK = qw/mux_handle/;

sub import {
    my $class = shift;
    my ($in) = @_;

    return unless $in;
    if ($in eq 'mux_handle') {
        my $caller = caller;
        no strict 'refs';
        *{"$caller\::mux_handle"} = \&mux_handle;
        return 1;
    }

    my $file = $in;

    mux_handle(\*STDOUT, $file, 'Test2::Plugin::IOMuxer::STDOUT');
    mux_handle(\*STDERR, $file, 'Test2::Plugin::IOMuxer::STDERR');

    mux_handle(Test2::API::test2_stdout(), $file, 'Test2::Plugin::IOMuxer::STDOUT') if Test2::API->can('test2_stdout');
    mux_handle(Test2::API::test2_stderr(), $file, 'Test2::Plugin::IOMuxer::STDERR') if Test2::API->can('test2_stderr');

    test2_add_callback_post_load(sub {
        my @handles;

        my $hub = test2_stack()->top;
        my $formatter = $hub->format or next;

        for my $meth (qw/handles io/) {
            if ($formatter->can($meth)) {
                my @list = $formatter->$meth;
                @list = @{$list[0]} if @list == 1 && ref($list[0]) eq 'ARRAY';
                push @handles => @list;
            }
        }

        mux_handle($_, $file, 'Test2::Plugin::IOMuxer::FORMAT') for @handles;
    });

}

sub mux_handle(*$;$) {
    my ($fh, $file, $layer) = @_;

    $layer ||= 'Test2::Plugin::IOMuxer::Layer';

    my $fileno = fileno($_[0]);
    die "Could not get fileno for handle" unless defined $fileno;

    if (my $set = $Test2::Plugin::IOMuxer::Layer::MUXED{$fileno}) {
        return if $set eq $file;
        confess "Handle (fileno: $fileno) already muxed to '$set', cannot mux to '$file'";
    }

    $Test2::Plugin::IOMuxer::Layer::MUXED{$fileno} = $file;

    unless($Test2::Plugin::IOMuxer::Layer::MUX_FILES{$file}) {
        open(my $mh, '>', $file) or die "Could not open mux file '$file': $!";
        $mh->autoflush(1);
        $Test2::Plugin::IOMuxer::Layer::MUX_FILES{$file} = $mh;
    }

    binmode($_[0], ":via($layer)");
}

1;

__END__