File Coverage

blib/lib/Test2/Plugin/IOMuxer/Layer.pm

Criterion	Covered	Total	%
statement	67	80	83.7
branch	17	24	70.8
condition	2	3	66.6
subroutine	11	11	100.0
pod	0	3	0.0
total	97	121	80.1

package Test2::Plugin::IOMuxer::Layer;
use strict;
use warnings;

BEGIN {
    local $@ = undef;
    my $ok = eval {
        require JSON::MaybeXS;
        JSON::MaybeXS->import('JSON');
        1;
    };

    unless($ok) {
        require JSON::PP;
        *JSON = sub() { 'JSON::PP' };
    }

    my $json = JSON()->new->utf8(1);

    sub encode_json { $json->encode(@_) }
}

use Time::HiRes qw/time/;

our $VERSION = '0.000008';

use Test2::Plugin::OpenFixPerlIO;
use IO::Handle;

our %MUXED;
our %MUX_FILES;

sub name { 'other' }

sub PUSHED {
    my ($class, $mode, $handle) = @_;
    $handle->autoflush(1);
    bless {buffer => [], handle => $handle, count => 0}, $class;
}

sub WRITE {
    my ($self, $buffer, $handle) = @_;

    my $count = ++$self->{count};

    if ($self->{DIED}) {
        print $handle $buffer;
        return length($buffer);
    }

    my $ok = eval {
        my $time   = time;
        my $fileno = fileno($handle);

        my @parts = split /(\n)/, $buffer;
        unshift @parts => '' if @parts == 1 && $parts[0] eq "\n";
        push @parts => undef if @parts % 2;
        my %parts = @parts;
        for my $part (@parts) {
            next unless defined $part;
            next if $part eq "\n";

            my $about = {stamp => $time, fileno => $fileno, name => $self->name, buffer => $part, write_no => $count};

            # Time to flush
            if ($parts{$part}) {
                $about->{buffer} .= $parts{$part}; # Put the \n back

                my $out;
                if (@{$self->{buffer}}) {
                    push @{$self->{buffer}} => $about;
                    $out = {
                        parts => $self->{buffer},
                        %$about,
                        buffer => join '' => map { $_->{buffer} } @{$self->{buffer}},
                    };

                    # Reset the buffer
                    $self->{buffer} = [];
                }
                else {    # Easy
                    $out = $about;
                }

                my $json = encode_json($out);
                my $mh   = $MUX_FILES{$MUXED{$fileno}};
                print $mh $json, "\n";
            }
            else {
                push @{$self->{buffer}} => $about;
            }
        }

        1;
    };
    my $err = $@;

    print $handle $buffer;

    unless ($ok) {
        $self->{DIED}++;
        die $err;
    }

    return length($buffer);
}

sub DESTROY {
    my $self = shift;
    my $handle = $self->{handle} or return;
    my $buffer = $self->{buffer} or return;
    return unless @$buffer;

    my $fileno = fileno($handle);

    my $out = {
        parts    => $self->{buffer},
        stamp    => time,
        fileno   => $fileno,
        name     => $self->name,
        write_no => ++$self->{count},
        DESTROY  => 1,
        buffer   => join '' => map { $_->{buffer} } @$buffer,
    };

    my $json = encode_json($out);
    my $mh = $MUX_FILES{$MUXED{$fileno}};
    print $mh $json, "\n";
}

1;

__END__